Как в Excel удалить текст до определённого символа

Удалить текст в ячейке Excel до первого пробела или другого символа можно формулой =ЗАМЕНИТЬ(A2;1;ПОИСК(" ";A2);""): ПОИСК находит позицию символа, а ЗАМЕНИТЬ стирает всё от начала строки до неё включительно. В Excel 365 то же делает =ТЕКСТПОСЛЕ(A2;" "). Чтобы убрать текст до последнего вхождения символа сразу во всём столбце, без формул, достаточно «Найти и заменить» со звёздочкой: Ctrl+H, найти «* », заменить на пустоту. А до первого или последнего вхождения, включая или не включая сам символ, это делает в пару кликов процедура !SEMTools.

Символом-границей может быть пробел, точка, запятая, двоеточие, целое слово или любая цифра — от этого зависит, какая формула нужна.

Убрать часть текста из ячеек

Если ненужный фрагмент одинаковый во всех ячейках («Артикул: », «г. », « руб.»), его проще всего удалить заменой на пустоту: выделите столбец, нажмите Ctrl+H, впишите фрагмент в поле «Найти», поле «Заменить на» оставьте пустым и нажмите «Заменить все». Формулой то же делает ПОДСТАВИТЬ:

Удалить текст до последнего символа в столбце

Наиболее просто удалить текст в диапазоне ячеек до последнего вхождения заданного символа или текста. Можно воспользоваться процедурой "Найти и заменить":

• выделить диапазон;
• вызвать процедуру поиска и замены со вкладки "Главная" или сочетанием клавиш Ctrl + H;
• использовать подстановочный символ * (звёздочку) прямо перед искомым в строке поиска;
• оставить пустым второе поле и нажать «ОК».

Процедура заменит все символы до знака на пустоту, иначе говоря, удалит их. Звездочка как раз и обозначает "все символы". Так будет выглядеть результат:

Звёздочка «жадная»: она захватывает максимум текста, поэтому «*,» удалит всё до последней запятой, а не до первой. Чтобы удалить до первого вхождения, нужна формула.

Удалить текст до последнего вхождения формулой

Если исходные данные нужно сохранить, удалить всё до последнего символа можно формулой. В Excel 365 — =ТЕКСТПОСЛЕ(A2;"\";-1) (минус единица — «первое вхождение с конца»). В более ранних версиях — через ПОДСТАВИТЬ, которая заменяет последнее вхождение на редкий символ «#», чтобы найти его позицию:

Удалить текст до первого пробела или символа формулой

Формула ниже удаляет всё до первого пробела включительно и работает с любым другим символом — достаточно заменить его в кавычках.

Однако удалить первое слово в ячейке — самая популярная задача, и пробел как раз и является символом, который отгораживает первое слово слева от остального текста.

=ЗАМЕНИТЬ(A2;1;ПОИСК(" ";A2);"")

Формулы для других символов аналогичны.

Убрать текст в ячейке до первой запятой:

=ЗАМЕНИТЬ(A2;1;ПОИСК(",";A2);"")

До точки:

=ЗАМЕНИТЬ(A2;1;ПОИСК(".";A2);"")

А чтобы удалить текст до вхождения последовательности символов, например, слова, нужно использовать в формуле длину этой последовательности, сократив её на 1.

Здесь из адресов удаляется текст до номера дома. Длина текста в кавычках - 3 символа (д, точка и пробел):

=ЗАМЕНИТЬ(A2;1;ПОИСК("д. ";A2)+2;"")

Удалить текст до второго вхождения символа

Чтобы удалить всё до второго (третьего, N-го) пробела, ПОДСТАВИТЬ с четвёртым аргументом заменяет нужное по счёту вхождение на «#», а ПСТР возвращает текст после него. В Excel 365 короче: =ТЕКСТПОСЛЕ(A2;" ";2).

Удалить текст до первой цифры

Напомню, как работают формулы выше:

1. excel-функция ПОИСК ищет позицию первого вхождения текстового паттерна (он всегда в кавычках). Соответствующий фрагмент выделен красным;
2. функция ЗАМЕНИТЬ принимает эту позицию как аргумент;
3. она же заменяет фрагмент от первого символа до этой позиции на пустоту (две кавычки подряд), таким образом, удаляя его.

Следовательно, чтобы удалить текст до первой цифры, нужно вычислить позицию первой цифры в строке. Поскольку цифр не одна, а 10, простая формула уже не подойдет. Но можно сделать это вот такой формулой массива:

{=МИН(ЕСЛИОШИБКА(ПОИСК(СИМВОЛ(СТРОКА(48:57));A1);""))}

А подставив это выражение в исходную формулу, мы сможем решить исходную задачу — получить текст после первой цифры включительно, удалив текст до неё.

{=ЗАМЕНИТЬ(A2;1;МИН(ЕСЛИОШИБКА(ПОИСК(СИМВОЛ(СТРОКА($48:$57));A2);""))-1;"")}

Что за числа 48 и 57, можно прочитать подробнее тут:

Функция СИМВОЛ в Excel

Обратите внимание на фигурные скобки! Их не нужно вводить, они появятся сами при вводе формулы сочетанием клавиш Ctrl + Shift + Enter.

Формула выдаст ошибку, если цифр в строке нет.

Удалить текст до символа в 1–2 клика с !SEMTools

Каждый из перечисленных способов хорош по-своему, но всем им недостает одного важного фактора - скорости исполнения.

В каждом из случаев нужно вводить много символов и производить много действий.

Для экономии времени я включил быстрые процедуры в меню своей надстройки для Excel - !SEMTools.

Теперь удалить текст до первого или последнего вхождения конкретного символа или подстроки, включая и не включая сам текст, можно в считанные мгновения!

При этом можно как менять данные на месте, так и автоматически выводить в соседний столбец - за это отвечает глобальный чекбокс.

Смотрите пример:

Почему формула не удаляет текст до символа — частые ошибки

• Ошибка #ЗНАЧ!. В ячейке нет искомого символа, и ПОИСК ничего не находит. Чтобы такие ячейки остались как есть, оберните формулу: =ЕСЛИОШИБКА(ЗАМЕНИТЬ(A2;1;ПОИСК(" ";A2);"");A2).
• Пробел «не находится», хотя он виден. Это неразрывный пробел (символ 160), он часто приходит из выгрузок с сайтов. Ищите его так: =ПОИСК(СИМВОЛ(160);A2) — или сначала уберите лишние и неразрывные пробелы.
• Удалилось до последнего вхождения, а не до первого. Так работает звёздочка в «Найти и заменить». Для первого вхождения используйте формулу.
• Неверно ищется «?», «*» или «~». Для ПОИСК это подстановочные знаки. Используйте функцию НАЙТИ — она ищет символы буквально и к тому же учитывает регистр.

Удалить текст до символа — частые вопросы

Как убрать часть текста в ячейке Excel?

Если фрагмент одинаковый — замените его на пустоту через Ctrl+H или формулой =ПОДСТАВИТЬ(A2;"фрагмент";""). Если нужно удалить всё до определённого символа — формулой =ЗАМЕНИТЬ(A2;1;ПОИСК(" ";A2);"").

Как удалить все символы до определённого знака?

До первого вхождения — =ЗАМЕНИТЬ(A2;1;ПОИСК(",";A2);""), в Excel 365 — =ТЕКСТПОСЛЕ(A2;","). До последнего вхождения во всём столбце — «Найти и заменить» с шаблоном «*,» и пустой заменой.

Как удалить текст до второго по счёту символа?

Формулой =ПСТР(A2;ПОИСК("#";ПОДСТАВИТЬ(A2;" ";"#";2))+1;1000) или в Excel 365 — =ТЕКСТПОСЛЕ(A2;" ";2).

Как удалить текст до символа, не удаляя сам символ?

Уменьшите позицию на единицу: =ЗАМЕНИТЬ(A2;1;ПОИСК(",";A2)-1;"") — запятая останется в начале результата.

Итоги: как удалить текст до символа

Надеюсь, на этой странице вы нашли то, что искали, и смогли удалить лишний текст в ячейках. Коротко о выборе способа:

Вас наверняка заинтересуют и похожие операции: удалить последние символы и извлечь символы из ячейки — например, текст между двумя символами.

Смотрите также по теме:

• Удалить последнее слово из ячейки;
• Удалить первое слово в ячейках Excel;
• Удалить первые N символов в ячейках;
• Извлечь первые N символов ячейки.