Удалить первый символ во всех ячейках Excel можно формулой =ПСТР(A2;2;1000) — она возвращает текст начиная со второго символа — или =ПРАВСИМВ(A2;ДЛСТР(A2)-1). Чтобы удалить первые N символов, замените 2 на N+1: =ПСТР(A2;4;1000) уберёт три символа слева. А прямо в исходных ячейках, без формул и дополнительного столбца, первые символы удаляет процедура !SEMTools в пару кликов.
Здесь речь о случаях, когда количество символов известно: один, два, три. Если нужно удалить всё до пробела, запятой или слова, смотрите статью о том, как удалить текст до символа, а символы в конце строки — как удалить последние символы.
Удалить первые N символов формулой
Для таких формул понадобятся функции ПСТР, ПРАВСИМВ и ДЛСТР. ПРАВСИМВ берёт из текста указанное количество символов справа, а ДЛСТР возвращает количество символов в ячейке. Чтобы удалить N символов слева, берём справа ДЛСТР − N символов:
=ПРАВСИМВ(A1;ДЛСТР(A1)-N)
Удалить первый символ
Чтобы убрать первый символ в ячейке, вычитаем из длины строки единицу:
| A | B | |
|---|---|---|
| 1 | Номер | Без первого символа |
| 2 | №1024 | 1024=ПРАВСИМВ(A2;ДЛСТР(A2)-1) |
| 3 | №1025 | 1025=ПРАВСИМВ(A3;ДЛСТР(A3)-1) |
| 4 | №2030 | 2030=ПРАВСИМВ(A4;ДЛСТР(A4)-1) |
| 5 | #A-17 | A-17=ПРАВСИМВ(A5;ДЛСТР(A5)-1) |
ДЛСТР(A2) равно 5, ПРАВСИМВ берёт 4 символа справа — «1024». Результат — текст, даже если в нём одни цифры.
В английском Excel: =RIGHT(A2,LEN(A2)-1)
Удалить первые N символов
Если нужно удалить сразу несколько первых символов, удобнее ПСТР: она возвращает текст, начиная с позиции N+1. Вторым аргументом ставим позицию, с которой текст нужно оставить, третьим — заведомо большое число:
| A | B | |
|---|---|---|
| 1 | Код | Без префикса |
| 2 | RU-48213 | 48213=ПСТР(A2;4;1000) |
| 3 | KZ-10077 | 10077=ПСТР(A3;4;1000) |
| 4 | BY-55120 | 55120=ПСТР(A4;4;1000) |
Три символа «RU-» удалены: ПСТР начинает с 4-го символа. Число 1000 — заведомо больше длины любого кода.
В английском Excel: =MID(A2,4,1000)
Альтернативный вариант с функцией ЗАМЕНИТЬ
Функция ЗАМЕНИТЬ заменяет N символов, начиная с первого, пустой строкой — то есть удаляет их:
=ЗАМЕНИТЬ(A1;1;N;"")
Где N — количество символов для удаления с начала строки.
| A | B | |
|---|---|---|
| 1 | Текст | Без 3 первых |
| 2 | SKU12345 | 12345=ЗАМЕНИТЬ(A2;1;3;"") |
| 3 | RU-Москва | Москва=ЗАМЕНИТЬ(A3;1;3;"") |
ЗАМЕНИТЬ подставляет пустую строку вместо 3 символов, начиная с первого.
В английском Excel: =REPLACE(A2,1,3,"")
Удалить символ в начале ячейки, только если он там есть
Если символ (точка, апостроф, «@») стоит в начале не всех ячеек, формула должна сначала проверить первый символ функцией ЕСЛИ и ЛЕВСИМВ:
| A | B | |
|---|---|---|
| 1 | Логин | Без «@» |
| 2 | @ivanov | ivanov=ЕСЛИ(ЛЕВСИМВ(A2;1)="@";ПРАВСИМВ(A2;ДЛСТР(A2)-1);A2) |
| 3 | petrov | petrov=ЕСЛИ(ЛЕВСИМВ(A3;1)="@";ПРАВСИМВ(A3;ДЛСТР(A3)-1);A3) |
| 4 | @sidorova | sidorova=ЕСЛИ(ЛЕВСИМВ(A4;1)="@";ПРАВСИМВ(A4;ДЛСТР(A4)-1);A4) |
| 5 | smirnov | smirnov=ЕСЛИ(ЛЕВСИМВ(A5;1)="@";ПРАВСИМВ(A5;ДЛСТР(A5)-1);A5) |
В A3 и A5 символа нет — формула возвращает текст без изменений. Замените «@» на любой символ, который нужно проверить.
В английском Excel: =IF(LEFT(A2,1)="@",RIGHT(A2,LEN(A2)-1),A2)
Удалить префикс в начале ячейки по условию
Чтобы удалить в начале ячейки целый фрагмент («г. », «ООО », «тел.»), сравниваем начало строки с ним и отрезаем ровно его длину:
| A | B | |
|---|---|---|
| 1 | Город | Без «г. » |
| 2 | г. Москва | Москва=ЕСЛИ(ЛЕВСИМВ(A2;3)="г. ";ПСТР(A2;4;1000);A2) |
| 3 | Казань | Казань=ЕСЛИ(ЛЕВСИМВ(A3;3)="г. ";ПСТР(A3;4;1000);A3) |
| 4 | г. Самара | Самара=ЕСЛИ(ЛЕВСИМВ(A4;3)="г. ";ПСТР(A4;4;1000);A4) |
| 5 | пос. Видное | пос. Видное=ЕСЛИ(ЛЕВСИМВ(A5;3)="г. ";ПСТР(A5;4;1000);A5) |
3 — длина префикса «г. » вместе с пробелом. Строки без префикса остаются как были.
В английском Excel: =IF(LEFT(A2,3)="г. ",MID(A2,4,1000),A2)
Если префиксов несколько, проще всего регулярное выражение: =REGEXREPLACE(A2;"^(г\.|пос\.|д\.) ";"") удалит любой из них. Точка в шаблоне экранируется обратной косой чертой.
| A | B | |
|---|---|---|
| 1 | Город | Без префикса |
| 2 | г. Тверь | Тверь=REGEXREPLACE(A2;"^(г\.|пос\.|д\.) ";"") |
| 3 | пос. Ильинский | Ильинский=REGEXREPLACE(A3;"^(г\.|пос\.|д\.) ";"") |
| 4 | д. Горки | Горки=REGEXREPLACE(A4;"^(г\.|пос\.|д\.) ";"") |
| 5 | Москва | Москва=REGEXREPLACE(A5;"^(г\.|пос\.|д\.) ";"") |
Точка в шаблоне экранирована обратной косой чертой, иначе она означает «любой символ». Ячейки без префикса не меняются.
Удалить цифры или буквы в начале ячейки
Удалить цифры в начале ячейки
Если после цифр в начале стоит пробел (артикул и название товара), удаляем всё до первого пробела включительно:
| A | B | |
|---|---|---|
| 1 | Товар | Без артикула |
| 2 | 1024 Чайник электрический | Чайник электрический=ПСТР(A2;ПОИСК(" ";A2)+1;1000) |
| 3 | 77 Кружка | Кружка=ПСТР(A3;ПОИСК(" ";A3)+1;1000) |
| 4 | 305 Термос 1 л | Термос 1 л=ПСТР(A4;ПОИСК(" ";A4)+1;1000) |
Цифры внутри названия («1 л») не пострадают: формула режет только до первого пробела.
В английском Excel: =MID(A2,SEARCH(" ",A2)+1,1000)
Удалить буквы в начале ячейки
Чтобы удалить все буквы и знаки до первой цифры, находим позицию первой цифры: НАЙТИ ищет каждую из цифр 0–9, а МИН выбирает самую левую. Дописанные «0123456789» страхуют от ошибки, если какой-то цифры в строке нет:
| A | B | |
|---|---|---|
| 1 | Код | С первой цифры |
| 2 | ART12345 | 12345=ПСТР(A2;МИН(НАЙТИ({0;1;2;3;4;5;6;7;8;9};A2&"0123456789"));1000) |
| 3 | SKU-77 | 77=ПСТР(A3;МИН(НАЙТИ({0;1;2;3;4;5;6;7;8;9};A3&"0123456789"));1000) |
| 4 | Партия 2026-10 | 2026-10=ПСТР(A4;МИН(НАЙТИ({0;1;2;3;4;5;6;7;8;9};A4&"0123456789"));1000) |
Если в ячейке нет ни одной цифры, формула вернёт пустую строку.
В английском Excel: =MID(A2,MIN(FIND({0,1,2,3,4,5,6,7,8,9},A2&"0123456789")),1000)
Удалить первые символы регулярным выражением
Крайне мощный инструментарий для удаления символов из текста даёт использование регулярных выражений. С их помощью можно удалить практически любой текст, будь то в начале, середине или конце ячейки. Главное - хорошо знать синтаксис регулярных выражений.
В Excel 365 есть встроенная функция РЕГЗАМЕНИТЬ (REGEXREPLACE). В более ранних версиях функции регулярных выражений появляются после установки !SEMTools и работают даже в бесплатной версии.
Удалить первый символ регуляркой
Выражение «^.» означает «первый символ в начале строки»:
=REGEXREPLACE(A1;"^.";"")Удалить первые N символов регуляркой
Чтобы убрать несколько символов в начале (например, 3), используем шаблон:
=REGEXREPLACE(A1;"^.{3}";"")| A | B | C | |
|---|---|---|---|
| 1 | Текст | Без первого символа | Без 3 первых |
| 2 | АБВ-125 | БВ-125=REGEXREPLACE(A2;"^.";"") | -125=REGEXREPLACE(A2;"^.{3}";"") |
| 3 | #Москва | Москва=REGEXREPLACE(A3;"^.";"") | сква=REGEXREPLACE(A3;"^.{3}";"") |
Точка — любой символ, {3} — ровно три раза, ^ — начало строки.
В английском Excel: =REGEXREPLACE(A2,"^.{3}","")
Удалить все цифры в начале ячейки регуляркой
Если цифры находятся только в начале ячейки:
=REGEXREPLACE(A1;"^\d+";"")Удалить все буквы в начале ячейки регуляркой
Шаблон (латиница+кириллица):
=REGEXREPLACE(A1;"^[A-Za-zА-Яа-яЁё]+";"")| A | B | C | |
|---|---|---|---|
| 1 | Текст | Без цифр в начале | Без букв в начале |
| 2 | 125 Ноутбук | Ноутбук=REGEXREPLACE(A2;"^\d+";"") | 125 Ноутбук=REGEXREPLACE(A2;"^[A-Za-zА-Яа-яЁё]+";"") |
| 3 | SKU125 | SKU125=REGEXREPLACE(A3;"^\d+";"") | 125=REGEXREPLACE(A3;"^[A-Za-zА-Яа-яЁё]+";"") |
Если в начале строки нет подходящих символов, текст не меняется. Пробел после удалённых цифр остаётся — его уберёт СЖПРОБЕЛЫ.
Удалить пробелы в начале ячейки регуляркой
Чтобы удалить все лишние пробелы в начале строки, потребуется следующая формула:
=REGEXREPLACE(A1;"^\s+";"")| A | B | C | D | |
|---|---|---|---|---|
| 1 | Текст | Без пробелов в начале | Длина до | Длина после |
| 2 | Москва | Москва=REGEXREPLACE(A2;"^\s+";"") | 9=ДЛСТР(A2) | 6=ДЛСТР(B2) |
| 3 | Тверь обл. | Тверь обл.=REGEXREPLACE(A3;"^\s+";"") | 13=ДЛСТР(A3) | 11=ДЛСТР(B3) |
Двойной пробел между словами остаётся: шаблон касается только начала строки.
Удалить первые символы в пару кликов с !SEMTools
Формулы выше требуют создания дополнительного столбца. Чтобы сэкономить время, если исходные данные не нужны, я разработал функции !SEMTools, удаляющие символы прямо на месте.
Если не уверены до конца в том, что делаете, можно использовать галочку "выводить результат справа" на панели надстройки.
Пошаговый алгоритм действий:
- Выделите диапазон ячеек
- На панели !SEMTools перейдите в раздел "Удалить" → "Символы" → "По позиции" → "С начала ячейки"
- Укажите количество символов для удаления
- Нажмите "ОК"
Смотрите наглядный пример:
Процедура не требует дополнительного столбца, работает на сотнях тысяч ячеек за секунды, а действие можно отменить.
Почему формула удаления первых символов выдаёт ошибку
- #ЗНАЧ! на пустых ячейках. ДЛСТР пустой ячейки — 0, и ПРАВСИМВ получает отрицательное число символов. Вариант с ПСТР такой ошибки не даёт: =ПСТР(A2;2;1000).
- Пропали ведущие нули. Результат формулы — текст «0125», но если потом превратить его в число, нули исчезнут. Для кодов оставляйте результат текстом.
- Удаляется не то, что видно в ячейке. Формулы работают со значением, а не с отображением: у даты 20.10.2026 значение — число 46315, у числа с форматом «1 200 ₽» — 1200. Первым символом окажется цифра значения.
- Символ в начале не удаляется. Возможно, это не тот символ, который кажется: апостроф-признак текста («'0125») в значение не входит, а неразрывный пробел — это не обычный пробел. Проверьте первый символ формулой =КОДСИМВ(A2).
Удалить первые символы — частые вопросы
Как удалить первый символ во всех ячейках столбца?
Введите в соседний столбец =ПСТР(A2;2;1000), протяните вниз и замените формулы значениями. С !SEMTools первый символ удаляется прямо в выделенных ячейках.
Как убрать первые три символа в ячейке?
Формулой =ПСТР(A2;4;1000) или =ЗАМЕНИТЬ(A2;1;3;"").
Как удалить символ в начале, только если он есть?
Проверьте первый символ: =ЕСЛИ(ЛЕВСИМВ(A2;1)="@";ПСТР(A2;2;1000);A2).
Как удалить все буквы в начале ячейки?
Формулой =ПСТР(A2;МИН(НАЙТИ({0;1;2;3;4;5;6;7;8;9};A2&"0123456789"));1000) — она оставит текст с первой цифры.
Удалить первый символ или первые N символов во всех выделенных ячейках можно в пару кликов с !SEMTools — прямо на месте, без ПСТР, ДЛСТР и дополнительного столбца.
!SEMTools решает эту и сотни других задач в пару кликов!
Итоги: как удалить первые символы в Excel
Надеюсь, на этой странице вы нашли то, что искали, и смогли удалить первые символы в ячейках. Для разовой задачи хватит ПСТР или ЗАМЕНИТЬ, для условий — ЕСЛИ или регулярного выражения. Если обрезать символы приходится регулярно, быстрее делать это процедурой прямо на месте.
Вас наверняка могут заинтересовать похожие операции, смотрите подробнее:
Чётко Ясно Лаконично Огромная благодарность
Пример видео «обрезать справа не корректен!
Вы правы, интерфейс надстройки знатно обновился, актуализировал примеры.
Большое спасибо, помогли ясной и четкой подсказкой.