Удалить первое слово в ячейке Excel, удалить первые N слов в ячейках

Удалить первое слово из ячейки можно формулой =ЗАМЕНИТЬ(A2;1;ПОИСК(" ";A2&" ");""): ПОИСК находит первый пробел, а ЗАМЕНИТЬ стирает всё от начала строки до него включительно. Пробел, приписанный к тексту (A2&" "), нужен, чтобы формула не выдавала ошибку, если слово в ячейке одно. В Excel 365 то же делает =ТЕКСТПОСЛЕ(A2;" ";1;;;""), а удалить первое слово сразу во всём столбце, без формул и дополнительных столбцов, можно процедурой !SEMTools в 2 клика.

Иногда при работе с Excel возникает необходимость удалить первое слово или же несколько слов в начале фраз в ячейке. Для решения задачи вам потребуется объединить несколько функций программы.

Задача удаления первого слова является частным случаем более общей (см. статью): «Как в Excel удалить текст до определенного символа».

Удалить первое слово из ячейки: составляем формулу

Технически, первое слово — это все символы в ячейке до первого пробела или до конца строки, если слово в ячейке всего одно. Как его удалить?

Находим позицию первого пробела

Есть 2 варианта формул, оба требуют сначала найти позицию первого символа пробела в строке, это делается с помощью функции ПОИСК или функции НАЙТИ. Обе ищут позицию в ячейке первого вхождения значения, указанного в первом аргументе, просматривая ячейку (второй аргумент) слева направо.

А что, если слово в строке одно, и пробела там нет? Обе функции вернут ошибку. Но её можно обойти, производя поиск не в самой ячейке, а в тексте ячейки с присоединенным к нему справа пробелом (&" "). Смотрите пример:

Может быть и другая неприятная ситуация — в начале ячейке может быть лишний пробел, что может нам испортить решение задачи. Если есть такая вероятность, рекомендуется сначала удалить лишние пробелы.

Заменяем фрагмент до первого пробела на пустоту

Теперь, когда нам известна позиция первого символа идущего после слова, ею можно воспользоваться, чтобы заменить слово на пустоту, что эквивалентно его удалению. Пустота обозначается кавычками, между которыми ничего нет ("").

Нам потребуется функция «ЗАМЕНИТЬ». Ей мы указываем ячейку, в которой производится замена, начиная с какой позиции, сколько символов, и на что заменим этот промежуток. Обратите внимание - функция не выдает ошибку в последней строке, несмотря на то, что в ячейке A8 меньше символов, чем число, которое мы ей указываем в B4.

Чтобы не создавать два столбца, можно совместить формулы в одну составную. Просто заменим в формулах третьего столбца ссылки на формулы второго столбца самими этими формулами. Так будет выглядеть итоговая составная формула удаления первого слова в ячейке для первой строки с данными:

=ЗАМЕНИТЬ(A2;1;ПОИСК(" ";A2&" ");"")

А ниже процесс, как происходит её создание:

Удалить первые N слов формулой

Если удалить нужно не одно, а несколько первых слов, ищем уже не первый, а N-й пробел. Функция ПОДСТАВИТЬ умеет заменять конкретное по счёту вхождение, этим и воспользуемся. Количество слов — в ячейке B1:

=ЕСЛИОШИБКА(ПСТР(A2;НАЙТИ("\";ПОДСТАВИТЬ(A2&" ";" ";"\";$B$1))+1;ДЛСТР(A2));"")

Формула заменяет N-й пробел на символ «\», находит его позицию и забирает всё, что идёт после. Пробел, добавленный в конце строки, нужен для случая, когда слов ровно N: тогда результат будет пустым, а не ошибкой. Если слов меньше N, ЕСЛИОШИБКА тоже вернёт пустую строку.

В Excel 365 то же самое делает функция ТЕКСТПОСЛЕ:

=ТЕКСТПОСЛЕ(A2;" ";$B$1;;;"")

Удалить определённое слово из всех ячеек

Часто нужно убрать не первое слово, а конкретное — например, «купить» из списка запросов, где оно стоит в разных местах. Для этого подходит функция ПОДСТАВИТЬ. Чтобы не задеть слова, внутри которых встречается искомое («купить» в «выкупить»), ищем слово вместе с пробелами по краям, а к самой строке пробелы приписываем:

=СЖПРОБЕЛЫ(ПОДСТАВИТЬ(" "&A2&" ";" купить ";" "))

Без формул то же самое делает «Найти и заменить» (Ctrl+H): в поле «Найти» введите слово, поле «Заменить на» оставьте пустым. Но так удаляются и фрагменты внутри других слов, а между оставшимися словами появляются двойные пробелы. Если удалить нужно целый список слов, удобнее удаление слов по списку в !SEMTools.

Удалить первое слово в ячейках в 2 клика

Как видно, формулы выше не очень просты, и требуется время, даже чтобы просто их написать. Помимо этого, формулы требуют создания дополнительного столбца (или двух). Надстройка !SEMTools поможет упростить и ускорить решение задачи. Ниже показан пример удаления первых слов в ячейках, прямо на месте:

В примере ниже удаляем уже 2 слова в начале всех ячеек столбца:

Аналогично решается задача для трёх и более слов — можно использовать пункт «Первые N», чтобы указать количество удаляемых слов самостоятельно.

Почему формула удаляет не то слово

• Ничего не удаляется. В начале ячейки стоит пробел: ПОИСК находит его на позиции 1 и стирает только его. Сначала удалите лишние пробелы или оберните ячейку в СЖПРОБЕЛЫ: =ЗАМЕНИТЬ(СЖПРОБЕЛЫ(A2);1;ПОИСК(" ";СЖПРОБЕЛЫ(A2)&" ");"").
• Ошибка #ЗНАЧ!. В формуле нет «&" "», и в ячейке всего одно слово — пробел не найден.
• Слова разделены неразрывным пробелом. Текст, скопированный с сайтов, часто содержит СИМВОЛ(160) вместо обычного пробела. Замените его: =ПОДСТАВИТЬ(A2;СИМВОЛ(160);" ").
• Удалилось «слово» вроде «г.» или «№». Для формулы слово — любые символы до пробела, включая сокращения и знаки. Если нужно удалить только буквенные слова, проще удалить текст до определённого символа.

Удаление слов в Excel — частые вопросы

Как удалить первое слово в ячейке Excel?

Формулой =ЗАМЕНИТЬ(A2;1;ПОИСК(" ";A2&" ");""), протянутой по столбцу, или процедурой !SEMTools «Удалить → Слова → Первое».

Как удалить первые два слова?

Формулой =ЕСЛИОШИБКА(ПСТР(A2;НАЙТИ("\";ПОДСТАВИТЬ(A2&" ";" ";"\";2))+1;ДЛСТР(A2));"") или в Excel 365 — =ТЕКСТПОСЛЕ(A2;" ";2;;;"").

Как удалить определённое слово из всех ячеек?

Формулой =СЖПРОБЕЛЫ(ПОДСТАВИТЬ(" "&A2&" ";" купить ";" ")) или через «Найти и заменить» (Ctrl+H) с пустым полем «Заменить на».

Как удалить последнее слово?

Аналогичным приёмом с поиском последнего пробела — подробно в статье как удалить последнее слово в ячейке.

Итоги: как удалить первое слово в Excel

Надеюсь, на этой странице вы нашли то, что искали. Вас наверняка заинтересуют и похожие операции: удалить последнее слово и удалить повторяющиеся слова.