Возможности !SEMTools
↑ Навигация по задачам в Excel и возможностям надстройки !SEMTools ↑

Все специальные символы в Excel – исчерпывающее руководство

, создатель !SEMToolsОбновлено 17 мин чтенияРубрики: Основы Excel, Текст и символы

Специальные символы Excel это знаки, которые в ячейке или формуле работают как команда, а не как текст. «=» начинает формулу, «$» закрепляет ссылку, «*» и «?» заменяют любые символы при поиске, «&» склеивает текст, а «>=» сравнивает два значения. Ниже собраны все такие символы с примерами, в конце есть сводная таблица.

Нужен значок для оформления документа, например галочка, диаметр, градус, евро или стрелка? Это не спецсимвол, а обычный символ Юникода, и вставляется он функцией ЮНИСИМВ, функцией СИМВОЛ или через «Вставка → Символ». Популярные значки с кодами собраны в статье значки в Excel.

Функция ЮНИСИМВ - примеры специальных значков

Ниже — все символы, которые в Excel работают не как обычный текст, а как часть синтаксиса. Коротко:

СимволЧто делаетГде подробнее
* ? ~подстановочные знаки: любые символы, один символ, экранированиеподстановочные символы
=начинает формулу; внутри формулы — сравнение «равно»знак равенства
'делает содержимое ячейки текстомапостроф
&склеивает текстамперсанд
$закрепляет столбец или строку в ссылкезнак доллара
" "обозначают текст внутри формулыкавычки
!отделяет имя листа от адреса ячейкивосклицательный знак
[ ]имя книги, столбцы умных таблиц, условия в форматахквадратные скобки
; : пробелразделяют аргументы, задают диапазон и пересечениеразделители
= <> > < >= <=сравнивают значения, результат ИСТИНА или ЛОЖЬоператоры сравнения
+ - * / ^ %сложение, вычитание, умножение, деление, степень, процентматематические операторы
--превращает ИСТИНА/ЛОЖЬ и числа-текст в числадвойное отрицание
# @ { }динамические массивы, неявное пересечение, константы массивасимволы массивов

Подстановочные символы в Excel

Звездочка (*) и знак вопроса среди всех спецсимволов, используемых в Excel, вызывают, пожалуй, наибольшее количество вопросов у начинающих пользователей. Однако являются очень полезными. Они являются подстановочными, иными словами, подставляются в строку вместо других символов, лишь обозначая их неким образом.

Каким образом? Все просто:

  • Знак вопроса обозначает один любой символ, абсолютно любой, будь то цифра, буква, пробел или что-то более экзотическое, как неразрывный пробел или знак табуляции.
  • Звездочка (*) обозначает любое количество любых символов, включая их отсутствие.

Использование спецсимволов при поиске

Подстановочные спецсимволы наиболее полезны при использовании штатной процедуры Excel "Найти и заменить". Вот некоторые примеры:

Находим с помощью подстановочных символов все числа, состоящие из одного знака
Находим все числа, состоящие из одного знака

Обратите внимание на использование галочки "ячейка целиком". Именно благодаря ей поиск происходит не по содержимому внутри ячейки, а иначе, искомое сравнивается целиком со всей ячейкой.

Находим с помощью подстановочных символов и выделяем двузначные числа, заканчивающиеся на 7
Находим и выделяем двузначные числа, заканчивающиеся на 7
Находим с помощью подстановочных символов и выделяем все ячейки, начинающиеся на 7
Находим и выделяем все ячейки, начинающиеся на 7

Как найти символ * (звездочку) и вопросительный знак

Поскольку звёздочка и знак вопроса сами по себе могут присутствовать в текстах и их тоже может быть необходимость найти, необходимо дать Excel понять, что в данный момент поиска эти символы нужно воспринимать не как спецсимволы, а буквально.

Разумеется, в Microsoft это предусмотрели и это можно сделать, поставив перед ними знак "~" именуемый Тильда и находящийся обычно в верхнем левом углу клавиатуры.

Забавно, что и сам знак Тильда тоже нужно экранировать им же самим, чтобы его найти, иначе Excel его не найдет.

поиск спецсимволов в Excel
Как найти знак вопроса, звездочку и знак Тильда в Excel

Использование при фильтрации и расширенным фильтром

Аналогично использованию в процедуре поиска, можно использовать подстановочные символы и при фильтрации данных. Как и при поиске и замене, здесь также работает механика экранирования.

Подстановочные символы в формулах

Помимо процедур, подстановочные символы можно использовать и в некоторых формулах. К таким относятся

Использование подстановочных символов с функцией СЧЁТЕСЛИ
Использование подстановочных символов с функцией СЧЁТЕСЛИ

Знак = (равно): начало формулы и сравнение

С символа «=» начинается любая формула: всё, что после него, Excel вычисляет. Если ввести 2+2, в ячейке останется текст, а =2+2 вернёт 4. Формулу можно начать и со знака «+» или «−»: это наследие старых табличных программ, Excel примет ввод и сам добавит «=» в начало.

Внутри формулы тот же знак — оператор сравнения. =A2=B2 возвращает ИСТИНА, если значения равны, и ЛОЖЬ, если нет. Первое «=» начинает формулу, второе сравнивает.

Знак = как оператор сравнения
C3=A3=B3
ABC
1Значение 1Значение 2Результат
2120120ИСТИНА=A2=B2
3120120ЛОЖЬ=A3=B3
4МосквамоскваИСТИНА=A4=B4

Число 120 и текст «120» для Excel разные значения, поэтому во второй строке ЛОЖЬ. А регистр букв «=» не различает: «Москва» и «москва» равны. Для сравнения с учётом регистра есть функция СОВПАД.

В английском Excel: =A2=B2

Если формула видна в ячейке как текст и не считается, причин обычно три: у ячейки текстовый формат, перед «=» стоит пробел или апостроф, или включён режим показа формул (Ctrl+` или Формулы → Показать формулы). А если наоборот нужно записать в ячейку текст, начинающийся с «=», смотрите следующий раздел.

Операторы сравнения: >, <, >=, <=, <>

Знак равенства внутри формулы открывает список из шести операторов сравнения. Каждый сравнивает два значения и возвращает ИСТИНА или ЛОЖЬ. Результат можно вывести в ячейку, но чаще его подставляют в ЕСЛИ, СЧЁТЕСЛИ или условное форматирование. В примерах ниже в ячейке B2 число 150.

ОператорЗначениеПримерРезультат
=равно=B2=100ЛОЖЬ
<>не равно=B2<>100ИСТИНА
>больше=B2>100ИСТИНА
<меньше=B2<100ЛОЖЬ
>=больше или равно=B2>=150ИСТИНА
<=меньше или равно=B2<=150ИСТИНА

«Больше или равно» и «меньше или равно» набираются двумя знаками подряд без пробела: сначала «>» или «<», потом «=». «Не равно» тоже пишется парой знаков «<>». Символы ≥, ≤ и ≠ из таблицы символов выглядят аккуратнее, но в формуле это просто текст, оператором они не работают.

Сравнивать можно не только числа. Текст сравнивается по алфавиту без учёта регистра: ="яблоко">"апельсин" вернёт ИСТИНА. Любое число Excel считает меньше любого текста, поэтому число, записанное как текст, в сравнении с числом даёт неожиданный результат.

Самое частое применение — условие в ЕСЛИ: =ЕСЛИ(B2>=100;"план выполнен";"не выполнен").

В функциях с условием — СЧЁТЕСЛИ, СУММЕСЛИМН и похожих — оператор пишется внутри кавычек вместе со значением: =СЧЁТЕСЛИ(B:B;"<>0") считает ненулевые, =СЧЁТЕСЛИ(A:A;"<>") — непустые ячейки, =СЧЁТЕСЛИ(A:A;"") — пустые. Значение из ячейки приклеивают амперсандом: =СУММЕСЛИ(B:B;">="&E1).

Математические знаки в начале ячейки

Наверняка большинство из вас сталкивались с тем, что, если текстовая ячейка начинается со знаков "плюс", "равенство" или "минус", Excel обычно отдает ошибку #ИМЯ.

Как знак равенства, минус и плюс вставить в начале ячейки? Дело в том, что равенство - незаменимый оператор формул Excel, а плюс и минус - математические операторы, которые нужно использовать только с числовыми значениями.

Чтобы эти символы воспринимались как текст, перед ними должен быть любой другой символ. Еще один вариант - ставить перед ними символ "'" (апострОф). Это еще один специальный символ Excel, который меняет значение ячейки на текстовое. С его помощью вы явно сообщаете Excel, что вводимое значение - просто текст и не должно восприниматься никак иначе. Собственно, Excel предлагает этот вариант при ручном вводе:

Апостроф как спецсимвол в Excel
Ошибка и рекомендации Excel при ручном вводе в ячейку знака минус, плюс или равенства с текстом после них, не распознаваемым как формула

Знак ' (апостроф) в Excel

Апостроф уже был упомянут в этой статье чуть выше, где помогал в начале ячейки использовать знак равенства без превращения её в формулу.

А все дело в том, что, будучи вставленным в начало ячейки, он несет важную информацию для Excel о том, что данные в ячейке - строго текстовые, и их не нужно воспринимать никак иначе.

Любопытный факт, что длина содержимого ячейки в некоторых случаях может измениться.

Апостроф и форматы ячеек Excel
Использование апострофа для форматирования дат, времени и процентов как текст.

Почему так?

Дело в том, что Excel часто автоматически обрабатывает вводимое значение ячейки и превращает его в число в визуально аналогично выглядящем формате. Например, "50%" будет фактически 0,5, а даты будут восприняты как целые числа. Подробнее об этом можно прочитать в статье про функцию ТЕКСТ

Сам апостроф при этом никак не определяется и не влияет на другие параметры ячейки. Её длина остается такой же, как и без него, а формулы, ссылающиеся на ячейку, не видят в ней апостроф. Иными словами, он никак не вредит данным, только делает их текстовыми.

Символ & (амперсанд) в Excel

Амперсанд в Excel при использовании в формулах является оператором конкатенации и нужен как более лаконичная замена функции СЦЕПИТЬ. Ниже две формулы, делающие абсолютно одно и то же действие - объединяющие ячейку A1, пробел и ячейку B1:

=СЦЕПИТЬ(A1;" ";B1)
=A1&" "&B1

Очевидно, вторая формула короче, к тому же не использует вложенность (не имеет скобок), что иногда бывает полезно при составлении сложных формул.

Еще одно свойство амперсанда - т.к. процедура сцепки является текстовой по самой её сути, конкатенация амперсандом не исключение, и даже при сцепке двух числовых значений формат результирующего значения ячейки будет текстовым.

Знак $ (доллар): абсолютные и относительные ссылки

В формулах знак доллара не имеет отношения к валюте. Он закрепляет часть ссылки, чтобы она не сдвигалась при копировании формулы:

  • A1 — относительная ссылка: при протягивании вниз превращается в A2, A3…, при протягивании вправо — в B1, C1…;
  • $A$1 — абсолютная: не меняется никогда;
  • $A1 — закреплён столбец, строка меняется;
  • A$1 — закреплена строка, столбец меняется.
Курс в абсолютной ссылке $E$2
C3=B3*$E$2
ABCDE
1ТоварЦена, $Цена, ₽Курс
2Ноутбук85080750=B2*$E$295
3Монитор12011400=B3*$E$2
4Мышь454275=B4*$E$2

Цена B2 сдвигается по строкам, а курс $E$2 во всех строках один. Без долларов формула в C3 ссылалась бы на пустую E3 и вернула 0.

В английском Excel: =B2*$E$2

Знаки $ ставят клавишей F4: курсор на ссылку в строке формул, каждое нажатие переключает A1 → $A$1 → A$1 → $A1. Подробно, с примерами смешанных ссылок, нарастающего итога и ВПР, — в статье абсолютные и относительные ссылки в Excel.

Кавычки в формулах Excel

Двойные кавычки говорят Excel: «это текст, не вычисляй его». Без них слово в формуле считается именем функции, диапазона или ошибкой #ИМЯ?. Что нужно знать:

  • Текст в формуле всегда в кавычках: =ЕСЛИ(B2>0;"оплачено";"долг"). Числа и ссылки на ячейки в кавычки не берут.
  • Число в кавычках — это текст. ="5"+1 Excel ещё посчитает, а вот сравнение =A2="5" вернёт ЛОЖЬ, если в A2 настоящее число 5.
  • Пустые кавычки "" — пустая строка. =A2="" проверяет, пуста ли ячейка, а =ЕСЛИ(B2=0;"";A2/B2) оставляет ячейку визуально пустой вместо ошибки.
  • Кавычка внутри текста удваивается. Чтобы получить текст Он сказал "да", пишут ="Он сказал ""да""". Четыре кавычки подряд """" — это текст из одной кавычки.
  • Кавычку можно вставить функцией СИМВОЛ(34) — так формула читается проще.
  • Условия в функциях пишутся в кавычках: =СЧЁТЕСЛИ(A:A;">100"). Если число в условии берётся из ячейки, кавычки закрывают перед ссылкой: =СЧЁТЕСЛИ(A:A;">"&D1).
Кавычки в формулах
B3=""""&A3&""""
AB
1ЗначениеРезультат формулы
2РомашкаСорт: Ромашка="Сорт: "&A2
3Ромашка"Ромашка"=""""&A3&""""
4Ромашка"Ромашка"=СИМВОЛ(34)&A4&СИМВОЛ(34)
5пусто=ЕСЛИ(A5="";"пусто";A5)
615ЛОЖЬ=A6=15

B2: текст в кавычках склеивается со значением ячейки. B3 и B4: два способа обернуть значение в кавычки. B5: "" — проверка на пустую ячейку. B6: в A6 текст «15», а в формуле число 15 — они не равны.

В английском Excel: =""""&A3&""""

Одинарные кавычки (апострофы) в формулах встречаются в одном месте — вокруг имени листа с пробелами: ='Продажи 2026'!B3, об этом в следующем разделе. А типографские кавычки-ёлочки « » для Excel обычный текст без особого смысла — как их поставить и заменить, рассказано в статье кавычки-ёлочки в Excel.

Восклицательный знак: ссылка на другой лист

Восклицательный знак отделяет имя листа от адреса ячейки: =Лист2!B3 — ячейка B3 на листе «Лист2». Его не нужно набирать: начните формулу, щёлкните по ярлыку другого листа и по ячейке, Excel вставит ссылку сам.

  • Если в имени листа есть пробел, дефис, скобки или имя начинается с цифры, оно берётся в апострофы: ='Отчёт май'!B3.
  • Если в имени листа есть сам апостроф, внутри ссылки он удваивается.
  • Диапазон на другом листе: =СУММ(Лист2!B2:B100). Сразу несколько листов подряд — трёхмерная ссылка =СУММ('Январь:Март'!B2) сложит B2 со всех листов от «Январь» до «Март».
  • Знак $ ставится после восклицательного знака: Лист2!$B$3.

Все способы сослаться на ячейку, лист или файл, включая гиперссылки, собраны в статье как сделать ссылку в Экселе.

Квадратные скобки в формулах

Квадратные скобки встречаются в Excel в четырёх ролях.

  • Имя другой книги. ='[Курсы.xlsx]Лист1'!$B$2 — ячейка B2 на листе «Лист1» файла Курсы.xlsx. Если файл закрыт, Excel покажет перед скобками полный путь к нему.
  • Столбцы умной таблицы. В таблице, созданной через Ctrl+T, ссылки пишутся по именам: =СУММ(Продажи[Сумма]) — весь столбец «Сумма» таблицы «Продажи», =[@Цена]*[@Кол-во] — значения из текущей строки. Служебные элементы: [#Заголовки], [#Данные], [#Итоги], [#Все].
  • Стиль ссылок R1C1. R[-1]C[2] — ячейка на строку выше и на два столбца правее. Скобки означают относительное смещение; включается стиль в Файл → Параметры → Формулы.
  • Числовые форматы. В пользовательском формате в скобках пишут цвет и условие: [Красный] окрашивает число, [>1000] задаёт условие, [ч]:мм показывает больше 24 часов.

В регулярных выражениях квадратные скобки означают набор символов, об этом рассказано в разделе про регулярные выражения ниже.

Разделители в формулах: точка с запятой, двоеточие, пробел

  • ; (точка с запятой) разделяет аргументы функции в русской версии Excel: =ЕСЛИ(A2>0;"да";"нет"). В английской версии вместо неё запятая, потому что запятая у нас — десятичный разделитель. Поэтому формула, скопированная с англоязычного сайта, выдаёт ошибку: замените запятые между аргументами на точки с запятой, а названия функций — на русские по таблице функций на русском и английском.
  • : (двоеточие) задаёт диапазон: A2:C10 — прямоугольник от A2 до C10, A:A — весь столбец, 2:2 — вся строка.
  • Пробел между двумя диапазонами — оператор пересечения: =СУММ(B2:D5 C1:C10) сложит только общие ячейки C2:C5. Случайный пробел в формуле поэтому даёт ошибку #ПУСТО!.
  • Несколько диапазонов в одной функции перечисляют через точку с запятой: =СУММ(A2:A10;C2:C10).
  • , (запятая) в русской версии — только десятичный разделитель в числах: =A2*1,2.

Математические операторы: +, −, *, /, ^, %

Арифметические знаки работают как на калькуляторе, только умножение записывается звёздочкой, а деление — косой чертой. В последнем столбце ссылки на статьи, где та же операция делается сразу для целого столбца, без формулы в соседней ячейке.

ОператорДействиеПримерДля диапазона
+сложение=B2+C2Как прибавлять в Excel
-вычитание, минус перед числом=B2-C2Вычесть число из диапазона
*умножение=B2*C2Умножить диапазон на число
/деление=B2/C2Разделить диапазон на число
^возведение в степень=2^10 даёт 1024, корень: =A2^(1/3)Функция СТЕПЕНЬ и корень
%процент, то же, что деление на 100=B2*20%Арифметические операторы

Порядок вычислений как в математике: сначала степень, потом умножение и деление, потом сложение и вычитание, затем склейка & и в последнюю очередь сравнение. Используйте круглые скобки, если сомневаетесь. Подробно об этом в разделе порядок арифметических действий. Одна особенность: отрицание считается раньше степени, поэтому =-2^2 даёт 4, а не −4.

Знаки × и ÷ из таблицы символов для формул не подходят: Excel видит в них текст и вернёт ошибку #ИМЯ?. В формулах только * и /.

Двойное отрицание --

Двойное отрицание «--» — два минуса подряд: первый меняет знак, второй возвращает обратно, а в результате ИСТИНА становится 1, ЛОЖЬ — 0, а текст «15» — числом 15. Так считают ячейки по условию без СЧЁТЕСЛИ:

Двойное отрицание в СУММПРОИЗВ
C5=СУММПРОИЗВ(--(B2:B4>0))
ABC
1ТоварОстатокЦена
2Ручка025
3Тетрадь1260
4Папка5140
5Итого с остатком2=СУММПРОИЗВ(--(B2:B4>0))

B2:B4>0 даёт массив {ЛОЖЬ;ИСТИНА;ИСТИНА}, «--» превращает его в {0;1;1}, СУММПРОИЗВ складывает: 2 товара в наличии.

В английском Excel: =SUMPRODUCT(--(B2:B4>0))

Символы массивов: #, @ и фигурные скобки

  • # после ссылки — весь динамический массив, который «разлился» из ячейки в Excel 365 и 2021: =СЧЁТЗ(C2#). Если массив станет длиннее, ссылка расширится сама.
  • @ перед ссылкой или функцией — неявное пересечение: взять одно значение вместо массива. Excel 365 часто сам добавляет @ в формулы из старых файлов, чтобы они считали как раньше. Внутри умной таблицы [@Цена] — значение из текущей строки.
  • { } в константах — массив прямо в формуле: =СУММ(СЧЁТЕСЛИ(A:A;{"Анна";"Олег"})) считает оба имени сразу. В русской версии элементы строки разделяют точкой с запятой, а строки — двоеточием: {1;2;3} — по горизонтали, {1:2:3} — по вертикали.
  • { } вокруг всей формулы — старая формула массива, введённая через Ctrl+Shift+Enter. Набирать эти скобки вручную нельзя, Excel ставит их сам.
Ссылка на разлившийся массив C2#
D2=СЧЁТЗ(C2#)
ABCD
1ИмяУникальныеЧисло
2АннаАнна=УНИК(A2:A5)2=СЧЁТЗ(C2#)
3ОлегОлег
4Анна
5Олег

УНИК в C2 возвращает список, который занимает столько строк, сколько уникальных имён. C2# ссылается на весь этот список, какой бы длины он ни был.

В английском Excel: =COUNTA(C2#)

Подробнее о массивах — в статье формулы массива в Excel.

Спецсимволы в регулярных выражениях

В регулярных выражениях — в функциях РЕГТЕСТ, РЕГИЗВЛЕЧЬ, РЕГЗАМЕНИТЬ и в процедурах !SEMTools — у символов . * + ? ^ $ | \ ( ) [ ] { } совсем другое значение, чем в формулах. Например, точка там — любой символ, а $ — конец строки. Этот синтаксис разобран отдельно в статье регулярные выражения в Excel.

Специальные символы Excel: вопросы и ответы

Что означает знак $ в формуле Excel?

Закрепляет столбец, строку или оба в ссылке, чтобы они не менялись при копировании формулы: $A$1, $A1, A$1. Ставится клавишей F4.

Что означает восклицательный знак в формуле?

Отделяет имя листа от адреса ячейки: Лист2!B3 — ячейка B3 на листе «Лист2».

Как вставить кавычки в формулу Excel?

Внутри текста кавычку удваивают: ="Он сказал ""да""". Или используют СИМВОЛ(34).

Что значат квадратные скобки в формуле?

Имя другой книги ([Книга.xlsx]Лист1!A1), столбец умной таблицы (Таблица1[Цена]) или смещение в стиле R1C1.

Почему формула с англоязычного сайта не работает?

В русском Excel аргументы разделяет точка с запятой, а не запятая, и функции называются по-русски.

Как записать в ячейку текст, начинающийся со знака =?

Поставьте перед ним апостроф: '=текст. Апостроф в ячейке не отображается.

Как в Excel написать «больше или равно»?

Двумя знаками подряд без пробела: >=, например =B2>=100. «Меньше или равно» пишется <=, «не равно» — <>.

Найти, удалить или заменить спецсимволы в целых столбцах можно прямо на месте — без подстановочных знаков, тильд и формул.
!SEMTools решает эту и сотни других задач в пару кликов!

Итоги: спецсимволы Excel

СимволЗначение
* ? ~подстановочные знаки в поиске, фильтрах и функциях
=начало формулы, сравнение
> < >= <= <>больше, меньше, больше или равно, меньше или равно, не равно
+ - * / ^ %сложение, вычитание, умножение, деление, степень, процент
--превращение в число
'текстовое содержимое ячейки; имя листа с пробелами
&склейка текста
$абсолютная ссылка
" "текст в формуле, "" — пустая строка
!разделитель листа и ячейки
[ ]книга, столбец таблицы, R1C1, формат
;разделитель аргументов
:диапазон
# @динамический массив, неявное пересечение
{ }константа массива

Надеюсь, на этой странице вы нашли то, что искали, и теперь знаете, как работают специальные символы в Excel. Чаще всего проблемы вызывают звёздочка и знак вопроса при поиске (их экранируют тильдой), текст, начинающийся с «=» или минуса (ставьте перед ним апостроф), и забытый знак $ при протягивании формулы.


Связанные статьи:
Значки в Excel: галочка, диаметр, градус, евро и другие
Как найти определенные символы в ячейках Excel
Как удалить лишние символы из всех ячеек
Как добавить символы в каждую ячейку диапазона

13 комментариев:

Дмитрий, здравствуйте! Подскажите пожалуйста, а когда про остальные символы допишете? Или это отдельная статья? Интересует «», например

Всем здравствуйте! Может кто то что то слышал про управляющие теги для выделения некоторых слов жирным шрифтом, курсивом, подчёркиванием или цветом в Excel как html-страницах?

Как заменить определенный символ? Например 1213446729 мне нужно заменить 1 которая 3 по счëту.

Подскажите, а есть спец символ, который будет преобразовывать формулу в значение, для использования в другой формуле?

Как найти (заменить) любую одну Цифру? Прикладная задача: скопирован пронумерованный список и необходимо удалить номера позиций, с тем, чтобы в отдельном столбце пронумеровать автоматически.

Оставить комментарий

Ваш адрес email не будет опубликован. Обязательные поля помечены *

*