Rounding in Excel brings numbers to a simpler form: prices to cents, quantities to whole units, times to the hour. There are quite a few functions for rounding numbers, dates and times. Let’s go through all of them, and through the situations where you need to round in a particular direction, from the simplest to the most complex formulas.
One important point first. The Decrease Decimal button on the Home tab only changes how a number looks: the cell still stores all the decimals, and they are used in calculations. To actually round a value, you need a function or a procedure that changes it.
ROUND: rounding to a given number of digits
The basic function is ROUND. It takes the number and the number of digits and rounds by the usual rules: 5 and above goes up.
=ROUND(3.456,2)
| A | B | C | |
|---|---|---|---|
| 1 | Number | Digits | ROUND |
| 2 | 3.456 | 2 | 3.46=ROUND(A2,B2) |
| 3 | 3.456 | 0 | 3=ROUND(A3,B3) |
| 4 | 1234 | -2 | 1200=ROUND(A4,B4) |
| 5 | 2.5 | 0 | 3=ROUND(A5,B5) |
| 6 | -2.5 | 0 | -3=ROUND(A6,B6) |
A negative number of digits rounds to the left of the decimal point: −2 means hundreds. A half always rounds away from zero: 2.5 → 3, −2.5 → −3.
returns 3.46. The number of digits can be zero (round to a whole number) or negative: =ROUND(1234,-2) returns 1200, rounding to hundreds.
Rounding to an integer: INT and TRUNC
For simple rounding to an integer, without the second argument, Excel has two functions: INT and TRUNC.
The INT function
INT rounds a number down to the nearest integer. The direction is always down:
=INT(3.7)
returns 3, and
=INT(-3.7)
| A | B | C | |
|---|---|---|---|
| 1 | Number | INT | TRUNC |
| 2 | 3.7 | 3=INT(A2) | 3=TRUNC(A2) |
| 3 | -3.7 | -4=INT(A3) | -3=TRUNC(A3) |
| 4 | 8.999 | 8=INT(A4) | 8=TRUNC(A4) |
INT always rounds down, so −3.7 becomes −4. TRUNC just cuts off the fraction, so −3.7 becomes −3. For positive numbers they give the same result.
returns −4.
The TRUNC function
TRUNC works a little differently. First, it has an optional second argument that sets how many decimals to keep. It’s zero by default, so with positive numbers the function works just like INT.
The second difference shows on negative numbers. TRUNC doesn’t round down, it simply cuts off the rest of the fraction, which for negative numbers means rounding up. So TRUNC(−3.7) returns −3, and TRUNC(−3.75,1) returns −3.7.
Round numbers up and down: ROUNDUP and ROUNDDOWN
To round up or down, Excel has the ROUNDUP and ROUNDDOWN functions. They take two arguments: the number and the number of decimals to round to.
Rounding up
ROUNDUP always rounds away from zero. For example:
=ROUNDUP(3.456,2)
=ROUNDUP(-3.456,2)
return 3.46 and −3.46, rounding up to hundredths. Since rounding goes by absolute value, ROUNDUP actually rounds negative numbers down.
Rounding down
ROUNDDOWN, on the contrary, rounds toward zero:
=ROUNDDOWN(-3.456,2)
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Number | ROUNDUP | ROUNDDOWN | ROUND |
| 2 | 3.456 | 3.46=ROUNDUP(A2,2) | 3.45=ROUNDDOWN(A2,2) | 3.46=ROUND(A2,2) |
| 3 | -3.456 | -3.46=ROUNDUP(A3,2) | -3.45=ROUNDDOWN(A3,2) | -3.46=ROUND(A3,2) |
| 4 | 3.451 | 3.46=ROUNDUP(A4,2) | 3.45=ROUNDDOWN(A4,2) | 3.45=ROUND(A4,2) |
ROUNDUP goes away from zero, ROUNDDOWN toward zero — for negative numbers that is the opposite of “up” and “down”. 3.451 shows the difference from ROUND: ROUNDUP still gives 3.46.
returns −3.45. The function behaves the opposite way: it rounds positive numbers down and negative numbers up, also by absolute value.
Round to a multiple: MROUND, CEILING, FLOOR
The functions below round numbers to the nearest multiple of a value. That’s useful for prices ending in .99, packaging by 6 or 12 units, time slots and many other tasks.
MROUND
MROUND rounds a number to the nearest multiple of the given value. It takes two arguments: the number and the multiple. For example, =MROUND(17,5) returns 15, and =MROUND(18,5) returns 20.
Both arguments must have the same sign, otherwise the formula returns #NUM!. =MROUND(-17,-5) works and returns −15.
| A | B | C | |
|---|---|---|---|
| 1 | Number | Multiple | MROUND |
| 2 | 17 | 5 | 15=MROUND(A2,B2) |
| 3 | 18 | 5 | 20=MROUND(A3,B3) |
| 4 | 2.47 | 0.25 | 2.5=MROUND(A4,B4) |
| 5 | -17 | -5 | -15=MROUND(A5,B5) |
| 6 | -17 | 5 | #NUM!=MROUND(A6,B6) |
17 is closer to 15 than to 20, 18 is closer to 20. The number and the multiple must have the same sign, otherwise #NUM!.
CEILING and FLOOR
CEILING and FLOOR round a number up and down to the nearest multiple. Both take two required arguments: the number and the significance. Neither the significance nor the result has to be an integer:
=CEILING(10.1,2)
returns 12, and
=FLOOR(10.9,3.33)
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Number | Significance | CEILING | FLOOR |
| 2 | 10.1 | 2 | 12=CEILING(A2,B2) | 10=FLOOR(A2,B2) |
| 3 | 10.9 | 3.33 | 13.32=CEILING(A3,B3) | 9.99=FLOOR(A3,B3) |
| 4 | -10.1 | 2 | -10=CEILING(A4,B4) | -12=FLOOR(A4,B4) |
For positive numbers CEILING goes up and FLOOR goes down to a multiple. With −10.1 and a positive significance, CEILING gives −10 (toward zero) and FLOOR −12 (away from zero).
returns 9.99.
CEILING and FLOOR with negative numbers
With negative numbers, the direction is not what the names suggest at first sight. CEILING(−10.1,2) rounds to −10, toward zero, and FLOOR(−10.1,2) rounds to −12, away from zero. In other words, CEILING always goes toward the larger number, and FLOOR toward the smaller one.
CEILING.MATH and FLOOR.MATH
The only difference of CEILING.MATH and FLOOR.MATH from their predecessors is the third argument, mode, which controls the direction for negative numbers. It doesn’t affect positive numbers.
If mode is 0 or omitted, the direction matches the name: CEILING.MATH(−10.1,2) returns −10, FLOOR.MATH(−10.1,2) returns −12. If mode is any non-zero number, negative numbers are rounded by absolute value: CEILING.MATH(−10.1,2,1) returns −12, and FLOOR.MATH(−10.1,2,1) returns −10. Also, the significance is optional here and is 1 by default.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Number | Mode | CEILING.MATH | FLOOR.MATH |
| 2 | -10.1 | 0 | -10=CEILING.MATH(A2,2,B2) | -12=FLOOR.MATH(A2,2,B2) |
| 3 | -10.1 | 1 | -12=CEILING.MATH(A3,2,B3) | -10=FLOOR.MATH(A3,2,B3) |
| 4 | 10.1 | 1 | 12=CEILING.MATH(A4,2,B4) | 10=FLOOR.MATH(A4,2,B4) |
With mode 0 the names work literally: CEILING.MATH(−10.1,2) = −10, FLOOR.MATH = −12. A non-zero mode flips the direction for negative numbers, and for positive numbers it changes nothing.
Apparently, these functions were created because the behavior of the old CEILING and FLOOR is fixed and not always convenient.
Round dates and times in Excel
Sometimes you need to round a date or time to a certain value. For dates, it’s usually the start of a week or month, for times, hourly or minute intervals.
Round a date to the start of the month
Build the first day of the month with the DATE function, taking the year and month from the date and typing 1 as the day:
=DATE(YEAR(A1),MONTH(A1),1)
Round a date to the start of the next month
The start of the next month is the day after the end of this month, which the EOMONTH function returns:
=EOMONTH(A1,0)+1
The same function can round a date to the start of this month, because its second argument shifts the month back and forth. Put −1 instead of 0 to get the end of the previous month, and add one day:
=EOMONTH(A1,-1)+1
Round a date to the start of the week
To round a date down to Monday of its week, subtract the day number from the WEEKDAY function (with type 2, Monday is 1):
=A1-WEEKDAY(A1,2)+1
| A | B | C | |
|---|---|---|---|
| 1 | Date | Task | Result |
| 2 | 10/22/2026 | start of month (DATE) | 10/01/2026=DATE(YEAR(A2),MONTH(A2),1) |
| 3 | 10/22/2026 | start of next month | 11/01/2026=EOMONTH(A3,0)+1 |
| 4 | 10/22/2026 | start of month (EOMONTH) | 10/01/2026=EOMONTH(A4,-1)+1 |
| 5 | 10/22/2026 | Monday of the week | 10/19/2026=A5-WEEKDAY(A5,2)+1 |
10/22/2026 is a Thursday, so its week starts on Monday 10/19/2026. Format the result cells as dates.
Rounding time to the hour
Sometimes you need to round a time to the start of the hour or to another interval. It’s convenient to set the interval in quotes in the usual time format and use MROUND, FLOOR, CEILING or their .MATH versions:
=MROUND(A1,"1:00")
=FLOOR(A1,"1:00")
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Time | MROUND "1:00" | FLOOR "1:00" | MROUND "0:15" |
| 2 | 9:20 | 9:00=MROUND(A2,"1:00") | 9:00=FLOOR(A2,"1:00") | 9:15=MROUND(A2,"0:15") |
| 3 | 9:45 | 10:00=MROUND(A3,"1:00") | 9:00=FLOOR(A3,"1:00") | 9:45=MROUND(A3,"0:15") |
| 4 | 13:08 | 13:00=MROUND(A4,"1:00") | 13:00=FLOOR(A4,"1:00") | 13:15=MROUND(A4,"0:15") |
MROUND rounds to the nearest hour: after 30 minutes it goes up. FLOOR always drops to the start of the hour. 13:08 rounds to 13:15 with a 15-minute step because 8 minutes is past the 7.5-minute midpoint.
The first one rounds to the nearest full hour, the second one to the start of the current hour. They return different values when more than 30 minutes have passed since the start of the hour.
In the same way, you can round a time to 15 or 5 minutes by setting the second argument to "0:15" or "0:05".
Why rounding gives unexpected results: common mistakes
- The number looks rounded, but the sum is off by a cent. The cells are only formatted with fewer decimals, and the sum uses the full values. Round with a function, not with the format.
- MROUND returns #NUM!. The number and the multiple have different signs.
- ROUNDUP rounded a negative number “down”. It rounds by absolute value. To always round toward the larger number, use CEILING.MATH.
- The rounded time shows a strange number. The result is a fraction of a day: apply a time format to the cell.
Rounding data in place with !SEMTools
Sometimes you want to round data in place, without creating extra columns or writing formulas. And the data must really be rounded, not just shown with fewer digits. Unfortunately, Excel has no built-in procedures for this. That’s why I added them to my !SEMTools add-in, in CHANGE → Numbers → Round: Round, Round up and Round down, each to a whole number, to 1 or 2 decimals or to N decimals. They use the same rules as Excel’s ROUND, ROUNDUP and ROUNDDOWN.
They’ve often come in handy in my work with numbers. Before rounding, I needed a dataset of random numbers, and a procedure from the Arithmetic operations section helped. I chose a range from 90 to 100, and then rounded to hundredths, tenths, integers and hundreds with different methods. Select the range, choose the method, done:
Round numbers up, down or to a multiple right in the source cells, without ROUND formulas or helper columns.
!SEMTools solves this and hundreds of other tasks in a couple of clicks!
Summary: which rounding function to choose
I hope you found what you were looking for on this page and were able to round your numbers the way you need. ROUND covers most cases, ROUNDUP and ROUNDDOWN set the direction, MROUND, CEILING and FLOOR round to multiples, and the .MATH versions give control over negative numbers. To round whole columns without formulas, use the !SEMTools procedures.
You may also be interested in other functions in the Excel functions reference.