HYPERLINK

This is an article about the HYPERLINK function. See also our guide on similar procedures and other tools: “10 ways to create a hyperlink in Excel”.

What does the HYPERLINK function do

The HYPERLINK function creates clickable hyperlinks in Excel cells — to websites, documents, sheets, files, folders, messengers, or even executable files. It’s useful because it allows you to specify both the path and custom display text — making links more understandable and visually appealing.

When clicked, Excel passes the path to the operating system, which opens the requested resource — whether it’s a website, document, folder, or application.

Hyperlinks created with this function look identical to manually inserted ones via right-click menu or Insert → Link tab, but offer much more flexibility when working with data.

Syntax

=HYPERLINK(link_location, [friendly_name])

• link_location — path to the resource (website, file, folder, range, sheet, macro, etc.)
• friendly_name — optional text that will display in the cell instead of the actual address

If you don’t specify friendly_name, Excel will display the address itself. Both arguments can be built using other Excel functions — referencing cell values, assembling URLs from parts, etc.

Usage examples

Website hyperlink

Which function would you use to add a website link to a cell? Of course, HYPERLINK:

=HYPERLINK("https://semtools.guru", "Go to website")

File and folder hyperlinks

The HYPERLINK function can open folders and even launch .exe files — without macros or add-ins. This can be convenient for creating control panels within workbooks. However, since this isn’t secure, Excel will warn you with a pop-up notification.

Hyperlink to Excel file:

=HYPERLINK("C:\Users\User\Documents\Report.xlsx", "Open report")

Network file:

=HYPERLINK("\\Server01\Projects\Plan.xlsx", "Project plan")

Link to computer folder:

=HYPERLINK("C:\Users\User\Downloads\", "Open downloads folder")

Internal Excel hyperlinks

Hyperlink to cell on current sheet:

=HYPERLINK("#A1", "To top")

Hyperlink to range on current sheet:

=HYPERLINK("#B2:B10", "To table")

Hyperlink to different sheet:

=HYPERLINK("#Sheet2!A1", "Open Sheet2")

With sheet name in quotes (if it contains spaces):

=HYPERLINK("#'Analytics 2024'!C5", "Go to analytics")

Hyperlink to different workbook (if open):

=HYPERLINK("[Finance.xlsx]Data!A1", "To finances")

If workbook is closed — specify full path:

=HYPERLINK("C:\Reports\[Finance.xlsx]Data!A1", "Open cell in file")

Hyperlink with dynamic sheet name from cell:

=HYPERLINK("#'"&A1&"'!A1", "Go to sheet "&A1)

Hyperlink to named range:

=HYPERLINK("#January_Sales", "To January sales")

Links to email, messengers, apps and macros

Excel supports not only website and document hyperlinks, but also special protocols:

mailto:
tg://
viber://

and others.

Email hyperlink:

=HYPERLINK("mailto:support@semtools.guru", "Contact support")

Email with subject and body:

=HYPERLINK("mailto:support@semtools.guru?subject=Error&body=Hello! I found an error!", "Report error")

Telegram channel hyperlink:

=HYPERLINK("tg://resolve/?domain=semtools", "!SEMTools Telegram channel")

WhatsApp chat by number:

=HYPERLINK("https://wa.me/79015052302", "Message author on WhatsApp")

Call link (on mobile devices or if Windows-phone connection is configured):

=HYPERLINK("tel:+74951234567", "Call office")

Dynamic hyperlinks

Hyperlinks can be built dynamically — depending on cell values, formulas, and conditions. This is especially useful for creating links to search, profiles, documents, reports, and other resources that change from row to row.

Example: building a website search link based on value in cell A2:

=HYPERLINK("https://google.com/search?q="&A2, "Search Google: "&A2)

Or hyperlink based on condition (using IF function):

=IF(B2="PDF",
HYPERLINK("https://site.com/files/"&A2&".pdf", "PDF file"),
"")

This way, unique hyperlinks can be generated for each row in a table, automatically substituting URL parameters, filenames, and other variables.

Working with relative and absolute paths

The HYPERLINK function can use both absolute and relative paths to files and folders. This determines whether the link will work when the workbook is moved or sent to other users.

Absolute path

Absolute path example:

=HYPERLINK("C:\Users\User\Documents\Report.xlsx", "Open file")

Such links only work on computers where the file actually exists at the specified path. Move the workbook to another computer — the path “breaks”.

Relative path

If the file being linked is in the same folder as the Excel workbook, you can specify just the filename:

=HYPERLINK("Report.xlsx", "Open adjacent file")

Or navigate to subfolder:

=HYPERLINK("archive\2024.xlsx", "File in archive folder")

Such links continue to work even if the workbook folder is moved or renamed — as long as the relative file locations remain the same.

Potential issues

• If you open the Excel file from an archive or email — relative paths won’t work
• Some cloud storage services (like OneDrive) substitute their own absolute paths — links may break when downloading local copies
• Excel may “remember” the absolute file path when first opened, even if the formula specifies relative — especially in older Office versions

It’s recommended to test relative links when sharing files with other users or working in teams.

Interactivity and formatting

Excel hyperlinks aren’t limited to underlined text. There are many ways to visually style links to make them more noticeable, understandable, or conversely, hidden from users.

Color and formatting

Excel applies the “Hyperlink” style by default — blue color with underline. This can be changed:

• Home tab → Styles → Cell Styles
• Right-click on “Hyperlink” style → Modify

Here you can set color, font, underline, and other parameters for both normal and followed link states.

Hidden hyperlinks

Sometimes you don’t want hyperlinks to appear as links. This can be done by:

• Setting the link color to match the background (e.g., white text on white background)
• Manually removing underline (via format)
• Placing hyperlink in a cell with a symbol, icon, or number

Hyperlinks with icons

You can use hyperlinks with symbol or icon values (like 🔗 or 📎):

=HYPERLINK("https://semtools.guru", "🔗")

You can also use emoji, Unicode special characters.

Practical applications and use cases

Hyperlinks in Excel aren’t just for websites. They become especially useful combined with analytics, filters, reports, and interactive tables.

Links in checklists and registries

If you have a task table, checklist, or journal, hyperlinks help quickly open related documents, templates, forms, folders, or even launch specific processes. Example:

=HYPERLINK("https://docs.site.com/task?id="&A2, "Task #"&A2)

Links to filtered reports

If your reporting system supports URL filtering (like Power BI, Looker Studio, Metabase), you can dynamically build links with filters:

=HYPERLINK("https://dashboard.site.com/report?manager="&A2, "Report for manager "&A2)

Hyperlink with variable logic (using VLOOKUP)

One of the most convenient methods — use a dropdown with link texts, while URLs come from a reference table using VLOOKUP function. This is great for creating navigation menus within Excel workbooks and saving space.

Step 1: Links table

Create a helper table somewhere nearby or on a separate sheet (you can even hide it):

Step 2: Dropdown list

Create a selection list in cell A2:

• Data → Data Validation → List
• Source: Buy,Download,Author

Step 3: Hyperlink formula

In adjacent cell (C2) use the formula:

=IFERROR(
HYPERLINK(
VLOOKUP(A2, $F$2:$G$4, 2, FALSE),
A2),
"")

Here $F$2:$G$4 is the links table range, A2 is the selected text. As a result, C2 will show an active hyperlink with text matching the selected item.

This post is also available in RU.