Функция ПРОПИСН в Excel делает все буквы текста заглавными (прописными): =ПРОПИСН(A2) превратит «москва» в «МОСКВА». Цифры, знаки и уже заглавные буквы не меняются. Обратная функция — СТРОЧН (все буквы строчные), а ПРОПНАЧ делает заглавной первую букву каждого слова. На английском ПРОПИСН называется UPPER, поэтому в английском Excel формула выглядит как =UPPER(A2).

Что делает функция ПРОПИСН

Эта функция позволяет сделать строчные (маленькие) буквы прописными (заглавными), иными словами, перевести их в верхний регистр. Символы в верхнем регистре и символы, для которых это неприменимо, не изменяются.

Синтаксис функции ПРОПИСН

=ПРОПИСН(текст)

ПРОПИСН: формат результата и исходных данных

См. ПРОПНАЧ

Первые слова ячеек целиком заглавными буквами ("капсом")

Наиболее часто такое может быть полезно при работе с ФИО в Excel. Фамилию обычно пишут целиком заглавными, а имя и отчество - просто с заглавной.

Допустим, в исходном списке все слова уже с заглавной буквы. Тогда формула потребует взять первое слово ячейки (в данном случае фамилию), преобразовать его в верхний регистр и добавить к нему остальные (имя и отчество).

Формула будет выглядеть так:

=ПРОПИСН(ЛЕВСИМВ(A1;ПОИСК(" ";A1)))&ПСТР(A1;ПОИСК(" ";A1)+1;1000)

Сделать заглавной первую букву ячейки

Казалось бы, что может быть проще, но вот поиск той самой первой буквы в ячейке так еще проблема, потянувшая на целую статью. А вот финальная формула массива оттуда:

{=ПОИСКПОЗ(ЛОЖЬ;СОВПАД(ПСТР(СТРОЧН(A1);СТРОКА(ДВССЫЛ("1:"&ДЛСТР(A1)));1);ПСТР(ПРОПИСН(A1);СТРОКА(ДВССЫЛ("1:"&ДЛСТР(A1)));1));0)}

Проверить, написан ли текст заглавными

Обычное сравнение «=» не различает регистр, поэтому для проверки используют СОВПАД: если текст совпадает со своей версией через ПРОПИСН, все буквы в нём уже заглавные.

Сделать прописными первые буквы предложений в Excel

Формула выше сделает прописной только одну, первую букву ячейки.

А если мы хотим сделать заглавными первые буквы предложений, которых в ячейке может быть несколько? Первую букву второго предложения и далее эта формула не определит и, следовательно, не решит задачу.

Есть ли решение? Да! Его предлагает моя надстройка !SEMTools для Excel. Читайте подробнее тут - изменить регистр букв в Excel.

Частые ошибки с ПРОПИСН

• Результат не обновляет исходные ячейки. ПРОПИСН работает в соседнем столбце; чтобы заменить исходные данные, скопируйте результат и вставьте как значения.
• Нужна заглавной только первая буква. ПРОПИСН меняет все буквы — используйте ПРОПНАЧ или формулу с ЛЕВСИМВ.
• #ИМЯ?. Ошибка в имени: функция пишется ПРОПИСН, на английском — UPPER.
• Число потеряло формат. ПРОПИСН возвращает текст: 0,5 станет «0,5» строкой.

Функция ПРОПИСН — частые вопросы

Что такое ПРОПИСН в Excel?

Функция, которая переводит все буквы текста в верхний регистр: =ПРОПИСН(A2).

Как ПРОПИСН называется на английском?

UPPER. Обратная функция СТРОЧН — LOWER, ПРОПНАЧ — PROPER.

Как сделать все буквы заглавными без формулы?

В Excel нет такой кнопки, как в Word. Без формул регистр меняют надстройки или Мгновенное заполнение (Ctrl+E) по образцу.

Как сделать заглавной только первую букву?

Формулой =ПРОПИСН(ЛЕВСИМВ(A2))&ПСТР(A2;2;1000).

Как проверить, что текст набран заглавными?

Формулой =СОВПАД(A2;ПРОПИСН(A2)).

Итоги: функция ПРОПИСН в Excel

Надеюсь, на этой странице вы нашли то, что искали. ПРОПИСН вместе с СТРОЧН и ПРОПНАЧ закрывает все задачи по изменению регистра формулами.

Функция СТРОЧН в Excel делает все буквы строчными: =СТРОЧН(A2) превратит «ООО «РОМАШКА»» в «ооо «ромашка»». Цифры, знаки и пробелы не меняются. Вместе с ПРОПИСН она даёт регистр «как в предложении» — =ПРОПИСН(ЛЕВСИМВ(A2))&СТРОЧН(ПСТР(A2;2;1000)), а для сравнения без учёта регистра — =СОВПАД(СТРОЧН(A2);СТРОЧН(B2)). Каждое слово с заглавной делает ПРОПНАЧ. На английском функция называется LOWER.

Что делает функция СТРОЧН

Функция переводит все символы (для которых это применимо) в передаваемом ей значении в нижний регистр.

Синтаксис функции СТРОЧН

=СТРОЧН(Текст)

СТРОЧН: формат результата и исходных данных

См. ПРОПНАЧ.

СТРОЧН - примеры применения

Допустим, наша задача - сделать в каждой ячейке первую букву заглавной, а остальные строчными. Исходная таблица дана полностью заглавными буквами.

Сразу оговоримся - функция ПРОПНАЧ здесь не подойдет, т.к. сделает каждое слово с заглавной, если их в ячейке несколько.

Для решения составим сложную формулу, в которой нам поможет функция ПСТР. Логика такова - первую букву оставим заглавной, а остальные - строчными.

Первую букву можно получить разными способами, может помочь как ПСТР,

=ПСТР(A1;1;1)

так и функция ЛЕВСИМВ:

=ЛЕВСИМВ(A1;1)

Все буквы кроме первой нам также поможет извлечь ПСТР (здесь 1000 - число, заведомо превышающее возможное количество символов в ячейке):

=ПСТР(A1;2;1000)

Ну а итоговая формула будет составлена из вышеуказанных с обработкой функциями СТРОЧН и ПРОПИСН:

=ПРОПИСН(ПСТР(A1;1;1))&СТРОЧН(ПСТР(A1;2;1000))

=ПРОПИСН(ЛЕВСИМВ(A1;1))&СТРОЧН(ПСТР(A1;2;1000))

Как видно из примера, эта комбинация не всегда дает тот результат, который хотелось бы получить, работая с форматированным текстом (подсвечено желтым)

Ведь фактически она не делает заглавными первые буквы ячеек, а делает заглавным первый символ, который не всегда бывает буквой. А если в строке несколько предложений, второе и далее функция не определит и не сделает первые символы в них заглавными.

Есть ли решение этой проблемы? Да! Но не в стандартном функционале Excel. Его предлагает моя надстройка. Подробнее об этом функционале - сделать заглавными первые буквы предложений в Excel.

СТРОЧН вместе с другими функциями

Чаще всего СТРОЧН нужна не сама по себе, а как часть формулы: чтобы привести ФИО к единому виду или сравнить значения, не обращая внимания на регистр.

Функция СТРОЧН, другие примеры

Функция СТРОЧН кажется такой незамысловатой и поэтому не такой уж и нужной. Но тут и парадокс - простота и и прямолинейность функции как раз и делают её востребованной в множестве задач.

Вот лишь те задачи, которые есть на этом сайте, и которые в Excel помогает решить функция СТРОЧН:

• Найти заглавные/строчные буквы в ячейке
• Чистка семантического ядра
• Посчитать слова в ячейках столбца
• Посчитать количество символов в ячейках Excel
• Как заменить первую букву ячейки и сделать её заглавной
• Извлечь латиницу в Excel
• Транслитерация в Excel, замена русских букв на английские и наоборот
• Удалить пунктуацию (знаки препинания) в Excel
• Найти определённые слова в ячейках
• Найти повторяющиеся слова в ячейках
• Обнаружить текстовые символы в ячейках Excel

Функция СТРОЧН — частые вопросы

Что делает функция СТРОЧН в Excel?

Переводит все буквы текста в нижний регистр.

Как сделать первую букву заглавной, а остальные строчными?

Формулой =ПРОПИСН(ЛЕВСИМВ(A2))&СТРОЧН(ПСТР(A2;2;1000)).

Какую функцию использовать, чтобы каждое слово начиналось с заглавной, а остальные буквы были строчными?

ПРОПНАЧ: =ПРОПНАЧ(A2).

Как называется СТРОЧН на английском?

LOWER. Парная функция — ПРОПИСН (UPPER).

Итоги: функция СТРОЧН в Excel

Надеюсь, на этой странице вы нашли то, что искали. СТРОЧН — простая функция, которая чаще всего работает внутри формул нормализации текста.

Функция СИМВОЛ в Excel возвращает символ по его коду в кодировке Windows (для русской Windows — 1251): =СИМВОЛ(10) — перенос строки, =СИМВОЛ(169) — ©, =СИМВОЛ(171) и =СИМВОЛ(187) — кавычки-ёлочки, =СИМВОЛ(65) — латинская A. Чаще всего её используют, чтобы склеить текст с переносом строки: =A2&СИМВОЛ(10)&B2 (у ячейки должен быть включён перенос текста). Код — от 1 до 255; символы вне этой таблицы, например ₽ или Δ, возвращает ЮНИСИМВ.

Что делает функция СИМВОЛ?

Эта функция преобразует целое число в символ, который ему соответствует в текущей кодировке ANSI, используемой операционной системой.

ВАЖНО: ANSI-кодировка - это собирательное понятие, их (кодировок) очень много, и таблица сопоставления чисел и символов будет разной в зависимости от того, какая указана в реестре вашей операционной системы.

Наиболее часто на русскоязычных системах Windows установлена кодировка Windows-1251 (она же cp1251).

Синтаксис функции СИМВОЛ

=СИМВОЛ(число)

Число должно быть от 1 до 255, в иных случаях функция выдаст ошибку #ЗНАЧ!

Коды символов и соответствующие им символы

Таблица ниже поможет быстро сориентироваться, когда нужны редко используемые символы. Наиболее востребованные из них:

• символ переноса строки - 10
• символ ™ - 153
• символ ® - 174
• символ © - 169
• кавычки-ёлочки ("") - 171 и 187
• знак "плюс-минус" (±) - 177

Функция СИМВОЛ - примеры

Помимо использования строго по назначению, функция СИМВОЛ может использоваться для иных задач в Excel, включая такие, где выступает вспомогательной.

Создать алфавит функцией СИМВОЛ в Excel

Удобный способ не вводить буквы с клавиатуры самостоятельно.

В зависимости от того, какой алфавит вы хотите создать в Excel, понадобятся разные диапазоны чисел.

Для английского языка это диапазоны 65-90 (заглавные) и 97-122 (строчные). Для русского алфавита - 192-223 и 224-255 соответственно.

По какой-то причине буква Ё не входит ни в один из этих диапазонов (см. таблицу выше), иными словами, русский алфавит в кодировке 1251 будет неполон, если взять только подряд идущие цифры. Код заглавной Ё - 168, строчной - 184.

Подробнее читайте в статье: Как создать алфавит в Excel

Комбинации с другими функциями

В комбинации с ПОИСК, НАЙТИ, СЧЁТ и СТРОКА в формуле массива функция СИМВОЛ позволяет найти латиницу в русском тексте или кириллицу в английском.

Также может помочь извлечь или удалить последнее слово во всех ячейках.

СИМВОЛ, ЮНИСИМВ и КОДСИМВ

СИМВОЛ знает только 255 кодов текущей кодировки. Для любых символов Юникода — валют, стрелок, эмодзи — используйте ЮНИСИМВ. Обратную задачу — узнать код символа — решает КОДСИМВ.

Почему СИМВОЛ работает не так — частые ошибки

• #ЗНАЧ!. Код меньше 1 или больше 255. Для кодов Юникода используйте ЮНИСИМВ.
• Вместо русской буквы — другой символ. Коды 128–255 зависят от кодировки Windows. На компьютере с другим языком системы формула вернёт иной символ — ЮНИСИМВ от этого не зависит.
• Перенос строки не виден. СИМВОЛ(10) вставлен, но у ячейки выключен «Перенос текста».
• Нет буквы Ё в алфавите. В кодировке 1251 Ё имеет код 168, ё — 184, они не входят в диапазоны 192–255.

Функция СИМВОЛ — частые вопросы

Что делает СИМВОЛ(10)?

Возвращает символ переноса строки. Формула =A2&СИМВОЛ(10)&B2 выведет значения двух ячеек в две строки.

Как узнать код символа?

Функцией =КОДСИМВ("А") — для кодировки Windows или =UNICODE("А") — для Юникода.

Как вставить кавычки-ёлочки формулой?

=СИМВОЛ(171)&A2&СИМВОЛ(187).

Как называется СИМВОЛ на английском?

CHAR. Например, CHAR(10) — перенос строки.

Итоги: функция СИМВОЛ в Excel

Надеюсь, на этой странице вы нашли то, что искали. СИМВОЛ удобна для переносов строк и привычных знаков, а для всего остального надёжнее ЮНИСИМВ.

Функция СОВПАД в Excel сравнивает два текста с учётом регистра и возвращает ИСТИНА, только если они полностью одинаковы: =СОВПАД(A2;B2) даст ЛОЖЬ для «Москва» и «москва», хотя обычное сравнение =A2=B2 вернёт ИСТИНА. С её помощью находят заглавные буквы — =НЕ(СОВПАД(СТРОЧН(A2);A2)) — и считают точные совпадения: =СУММПРОИЗВ(--СОВПАД(A2:A100;"Москва")). На английском функция называется EXACT.

Что делает функция СОВПАД

Эта функция сравнивает два элемента текста и определяет, являются ли они абсолютно одинаковыми.

Учитывается регистр символов, только слова, написанные одинаково и имеющие символы верхнего и нижнего регистра в одной и той же позиции, будут считаться равными.

Синтаксис функции СОВПАД

=СОВПАД(Текст1;Текст2)

Можно сравнить только два аргумента.

СОВПАД: формат результата и исходных данных

Как и все текстовые функции, функция преобразует числовой формат в натуральное число перед сравнением. Поэтому функция считает 200% и 2 (изначально в числовом формате) совпадающими текстовыми значениями.

Это касается форматирования как даты, даты-времени, времени, процентного и финансового формата.

СОВПАД - примеры формул

Умение различать регистр символов делает функцию крайне важной при работе с текстом в Excel. Разберем пару примеров.

Найти заглавные или строчные буквы

Функция может быть удобна, когда нужно найти в ячейке буквы в определенном регистре - например, вот по ссылке статья - как найти заглавные буквы в ячейках Excel.

Если описать итоги кратко, нам поможет логика и функция СТРОЧН:

1. переведем значение ячейки в нижний регистр
2. сравним результат с изначальным значением ячейки
3. если вернется ЛОЖЬ, - хотя бы одна заглавная буква была.
4. Вуаля!

А вот и формула:

=НЕ(СОВПАД(СТРОЧН(A1);A1))

Найти любые строчные буквы поможет аналогичная формула, но с функцией ПРОПИСН:

=НЕ(СОВПАД(ПРОПИСН(A1);A1))

Найти, есть ли буквы в ячейке

Если проверить, совпадают ли значения ячейки в верхнем и нижнем регистре, можно выявить, есть ли в ней буквы. Если буква была в нижнем, станет верхним, а если в верхнем - в нижнем, и только если букв в ячейке нет, она останется такой же, как была. Иероглифы не в счет.

Логично ведь, правда? :)

Соответствующая формула:

=НЕ(СОВПАД(ПРОПИСН(A1);СТРОЧН(A1)))

Другие примеры с функцией СОВПАД

Функция СОВПАД встречается и в других интересных формулах, смотрите статьи по ссылкам:

Как заменить первую букву ячейки и сделать её заглавной

Посчитать количество символов в ячейках Excel

Поиск нескольких значений / по нескольким условиям в Excel

Почему СОВПАД возвращает ЛОЖЬ — частые ошибки

• Значения выглядят одинаково. Лишний пробел, неразрывный пробел или латинская буква вместо русской. Проверьте длину ДЛСТР и коды символов.
• Нужно сравнить без учёта регистра. Используйте обычное =A2=B2 или приведите оба значения к СТРОЧН.
• Формула не принимается. В русском Excel аргументы разделяются точкой с запятой: =СОВПАД(A2;B2).

Функция СОВПАД — частые вопросы

Что делает функция СОВПАД в Excel?

Сравнивает два текста посимвольно с учётом регистра и возвращает ИСТИНА или ЛОЖЬ.

Чем СОВПАД отличается от знака «=»?

«=» не различает регистр, СОВПАД — различает.

Как найти ячейки с заглавными буквами?

Формулой =НЕ(СОВПАД(СТРОЧН(A2);A2)).

Как называется СОВПАД на английском?

EXACT.

Итоги: функция СОВПАД в Excel

Надеюсь, на этой странице вы нашли то, что искали. СОВПАД нужна везде, где важен регистр; в остальных случаях хватает обычного сравнения.

Функция ДЛСТР в Excel считает количество символов в ячейке вместе с пробелами: =ДЛСТР(A2). Без пробелов — =ДЛСТР(ПОДСТАВИТЬ(A2;" ";"")), количество слов — =ДЛСТР(СЖПРОБЕЛЫ(A2))-ДЛСТР(ПОДСТАВИТЬ(СЖПРОБЕЛЫ(A2);" ";""))+1, сколько раз встречается символ — =ДЛСТР(A2)-ДЛСТР(ПОДСТАВИТЬ(A2;",";"")). Числа и даты ДЛСТР считает по значению, а не по виду: для даты 21.10.2026 результат 5, потому что это число 46316. На английском функция называется LEN.

Что делает функция ДЛСТР?

Функцию часто называют "Длина строки", что не совсем корректно, потому что речь не о строке, а о строковом выражении значения аргумента.

Эта функция позволяет посчитать количество символов в ячейке, включая пробелы и цифры, в этом самом строковом выражении. Обратите внимание на примеры ниже.

• Хотя визуально 2500% это 5 символов, при преобразовании в текстовую строку это всего лишь 25, поэтому ДЛСТР возвращает 2.
• Даты преобразуются в целые числа, где единицей является 1.01.1900 - вот почему для неё функция возвращает длину 1.

Есть символ, который функция ДЛСТР вообще не учитывает. Это апостроф ('), когда он в начале ячейки. Если в начале ячейки идут два символа апострофа подряд, второй уже учитывается.

Почему так происходит? Дело в том, что апостроф в Excel — один из специальных символов-операторов, переводящий формат ячейки в текстовый.

Синтаксис функции ДЛСТР

=ДЛСТР(Аргумент)

Аргумент у функции один, он обязательный. В нем можно указывать как одну ячейку, так и другие вычисления с помощью формул. При использовании в функциях массива аргументом может быть диапазон ячеек.

ДЛСТР - форматирование

Если входящее значение не в текстовом формате, оно конвертируется в него.

Ячейки в формате даты воспринимаются как числа, поэтому содержат обычно 5 знаков (если это не даты, близкие к 1900 году).

Процентный формат также конвертируется в натуральное число, например, 2500% = 25 (2 символа, см. таблицу примеров выше).

Примеры формул, применение ДЛСТР

Функция часто используется как вспомогательная в составных формулах, в комбинации с другими текстовыми функциями.

При этом эти комбинации позволяют решать самые необычные задачи.

Пример 1. Посчитать слова

Как узнать, сколько слов в ячейке Excel? Обычно их на 1 больше, чем пробелов между ними. Если пробел один, значит слов - два, если два - то слов три, и так далее.

Если есть вероятность, что пробелов больше 1 между словами, или они есть в начале и конце ячейки, их можно устранить функцией СЖПРОБЕЛЫ.

Пробелы в строке можно посчитать, измерив длину строки в символах:

• с ними,
• без них,
• и вычислив разницу.

Как получить строку без пробелов? Тут поможет функция ПОДСТАВИТЬ.

Так будет выглядеть формула для ячейки A1, учитывающая все эти нюансы. СЖПРОБЕЛЫ удаляет лишние пробелы, ПОДСТАВИТЬ удаляет их, а ДЛСТР измеряет длину строк:

=ДЛСТР(СЖПРОБЕЛЫ(A1))-ДЛСТР(ПОДСТАВИТЬ(СЖПРОБЕЛЫ(A1);" ";""))+1

Пример 2 - посчитать встречаемость фрагмента в тексте

Есть ли в тексте определенный символ? И если есть, то сколько их?

Рассмотрим пару примеров формул.

Есть ли в ячейке лишние пробелы

Формула ниже проверит, есть ли в ячейке лишние пробелы. Это удобно, когда нужно не просто удалить пробелы, а узнать, были ли они вообще:

=ДЛСТР(СЖПРОБЕЛЫ(A1))<>ДЛСТР(A1)

Формула очевидна и довольно проста. Если длина ячейки после удаления лишних пробелов функцией СЖПРОБЕЛЫ равна исходной - значит, их в ней нет, а если наоборот, не равна - есть.

Обратите внимание, что, несмотря на то, что в самой постановке вопроса звучит условие ЕСЛИ, функция ЕСЛИ тут не нужна. Если равенство верное, Excel сам вставит в ячейку результат ИСТИНА, и ЛОЖЬ, если наоборот.

Сколько раз встречается символ или слово в тексте

По некой аналогии с предыдущим примером, мы можем производить не булевое (ДА-НЕТ, ИСТИНА-ЛОЖЬ) сравнение длин строки перед и после удаления символа или фрагмента, а вычислить разницу.

Если мы ищем один символ, это позволит сразу понять его встречаемость.

Для удаления произвольного символа из строки нам понадобится функция ПОДСТАВИТЬ.

Если же текстовый фрагмент длиной 2 и более символов - нам потребуется еще и поделить полученный результат на его длину:

=(ДЛСТР(A1)-ДЛСТР(ПОДСТАВИТЬ(A1;B1;"")))/ДЛСТР(B1)

В данной формуле исходный текст в ячейке A1, а подсчитываемый фрагмент - в ячейке B1.

Обратите внимание на 5 и 6 строки - поскольку функция "ПОДСТАВИТЬ" чувствительна к регистру, из текста ею не было удалено первое вхождение. Если нужно учитывать вхождения в любом регистре, могут понадобиться функции СТРОЧН или ПРОПИСН.

Подсчитываемый текстовый фрагмент может быть любой длины.

Еще момент - функция может быть непригодна для подсчета коротких слов, т.к. одно слово может быть частью другого.

Пример 3 - извлечь или удалить последнее слово

Зная количество пробелов в тексте, можно заменить последний из них на редкий символ, чтобы потом вычислить его позицию.

С этим нам, как и в предыдущем примере, поможет функция ПОДСТАВИТЬ - она позволяет заменить не только все определенные текстовые фрагменты в строке, но и определенное по порядку вхождение (первое, второе и т.д.).

Что это нам дает? Последний пробел - не что иное, как символ, отделяющий последнее слово от остальной части строки. И по его позиции далее уже нехитрыми манипуляциями удалить или извлечь его.

Подробно пример рассмотрен здесь: Удалить последнее слово в Excel

Пример 4 - удалить первые N символов / первое слово

Нехитрая комбинация функций ПРАВСИМВ, ПОИСК и ДЛСТР позволяет удалить из ячейки первое слово.

Механика проста:

1. вычисляем позицию первого пробела функцией ПОИСК,
2. вычитаем из длины строки (ДЛСТР) это число
3. Извлекаем функцией ПРАВСИМВ полученную разницу из исходной строки

Подробнее пример рассмотрен в статье про функцию ПРАВСИМВ.

Если же количество символов уже известно заранее, формула еще проще - нужны только ДЛСТР и ПРАВСИМВ:

=ПРАВСИМВ(A1;ДЛСТР(A1)-4)

Подробнее можно почитать тут: удалить первые N символов в ячейке.

Пример 5 - последние символы ячейки

Как бы ни звучало очевидно, позиция последнего символа в строке равна ее длине в символах. А поэтому, зная длину строки, можно, например:

• удалить последние символы в ячейке
• извлечь последние символы из ячеек

А ниже примеры, как заменить последний символ в ней, взяв на 1 символ меньше с помощью ЛЕВСИМВ, и конкатенации с нужным текстом через амперсанд:

=ЛЕВСИМВ(A1;ДЛСТР(A1)-1)&"Текст вместо последнего символа"

Или с помощью функции ЗАМЕНИТЬ, которая на вход возьмет длину строки как позицию заменяемого символа:

=ЗАМЕНИТЬ(A1;ДЛСТР(A1);1;"Текст вместо последнего символа")

Пример 6 - в формуле массива

Как посчитать все символы в диапазоне ячеек или столбце?

Здесь поможет формула массива на основе комбинации функции ДЛСТР и функции СУММ. Первая создаст массив значений длины каждой из ячеек диапазона, а вторая просуммирует эти значения:

={СУММ(ДЛСТР(ДИАПАЗОН))}

Аналогичным способом функциями МАКС и МИН можно посчитать длины самой длинной и самой короткой строк в диапазоне.

Фигурные скобки вводить не нужно, они появятся сами при вводе формулы массива сочетанием клавиш Ctrl + Shift + Enter (вместо обычного Enter).

Пример 7 - извлечь цифры

Подробно процесс рассмотрен в разделе соответствующей статьи - как извлечь цифры из ячеек Excel формулой.

Все примеры с ДЛСТР на сайте

Извлечь числа из текста ячеек в Excel
Извлечь латиницу в Excel
Заменить первую букву ячейки и сделать её заглавной
Посчитать количество символов в ячейках Excel
Посчитать слова в ячейках столбца
Посчитать цифры в ячейках и ячейки с цифрами
Поиск позиции первого числа в ячейке
Поиск с конца строки, справа налево в Excel
Поиск нескольких значений / по нескольким условиям в Excel
Удалить знаки препинания в Excel
Удалить первую букву / первые N символов в начале ячейки в Excel
Удалить последний символ / N символов в конце ячеек Excel
Удалить последние N слов в ячейках Excel
Разделить текст и цифры в Excel
Число и сумма прописью в Excel

Почему ДЛСТР считает не то — частые ошибки

• Длина больше, чем видно. В ячейке невидимые пробелы по краям, неразрывные пробелы или переносы строк. Проверьте =ДЛСТР(СЖПРОБЕЛЫ(A2)).
• Дата или число считаются «неправильно». ДЛСТР берёт хранимое значение: дата — 5 символов, 12,50 ₽ — «12,5». Для длины видимого текста используйте =ДЛСТР(ТЕКСТ(A2;"формат")).
• Апостроф в начале не считается. Он служебный — превращает содержимое в текст и не входит в значение.
• Слов на одно больше. Ячейка пустая или формула без СЖПРОБЕЛЫ — используйте вариант с ЕСЛИ из примера 1.

Функция ДЛСТР — частые вопросы

Что такое ДЛСТР в Excel?

Функция «длина строки»: возвращает количество символов в ячейке, включая пробелы.

Как посчитать символы без пробелов?

Формулой =ДЛСТР(ПОДСТАВИТЬ(A2;" ";"")).

Как посчитать двойные пробелы?

Формулой =(ДЛСТР(A2)-ДЛСТР(ПОДСТАВИТЬ(A2;" ";"")))/2.

Как посчитать символы в нескольких ячейках?

Формулой =СУММПРОИЗВ(ДЛСТР(A2:A100)).

Как называется ДЛСТР на английском?

LEN.

Итоги: функция ДЛСТР в Excel

Надеюсь, на этой странице вы нашли то, что искали. ДЛСТР — основа формул подсчёта и обрезки текста; помните, что она считает значение, а не вид ячейки.

Функция ЗАМЕНИТЬ в Excel меняет часть текста по позиции: =ЗАМЕНИТЬ(A2;5;3;"777") заменит 3 символа, начиная с 5-го, на «777». Если количество символов равно нулю, текст вставляется: =ЗАМЕНИТЬ(A2;4;0;"-") добавит дефис после третьего символа, а пустая строка удаляет символы: =ЗАМЕНИТЬ(A2;1;ПОИСК(" ";A2);"") уберёт всё до первого пробела. Если нужно заменить не по позиции, а конкретный текст, используйте ПОДСТАВИТЬ.

Что делает функция ЗАМЕНИТЬ?

ЗАМЕНИТЬ — это текстовая функция, которая позволяет заменить часть строки на другой текст по заданной позиции. Это особенно полезно, если нужно изменить определённое количество символов, начиная с конкретной позиции, например, маскировать номер телефона, править шаблоны или убирать лишние символы.

Нужно указать, где должна начинаться замена, сколько символов удалить и какой новый текст замены должен быть.

Если параметр "количество символов" равен нулю, производится вставка текста.

При этом текст вставляется после предыдущей позиции

Если позиция превышает количество символов в исходном тексте, заменяемый текст добавляется к текущему.

ЗАМЕНИТЬ - синтаксис

=ЗАМЕНИТЬ(Текст;НачальнаяПозиция;КоличествоСимволов;ЧемЗаменить) 

• Текст — исходная строка, в которой будет производиться замена.
• НачальнаяПозиция — номер позиции (счёт с 1), с которой начинается замена.
• КоличествоСимволов — сколько символов будет заменено.
• ЧемЗаменить — текст, который вставится на место удалённых символов.

ЗАМЕНИТЬ: формат результата и исходных данных

Логические значения конвертируются в текст с сохранением регистра.

Даты конвертируются в соответствующее им число в текстовом формате.

Для решения проблемы может понадобиться функция ТЕКСТ.

Примеры формул с функцией ЗАМЕНИТЬ

Рассмотрим несколько примеров формул Excel с функцией ЗАМЕНИТЬ.

Заменить первые 3 символа в тексте на "###":

=ЗАМЕНИТЬ("89101234567";1;3;"###") 

Умножить число в конце ячейки с текстом:

Формула заменяет последние 3 символа на их числовое значение, увеличенное на 10%. Если заменить нельзя — оставляет текст как есть.

=ЕСЛИОШИБКА(ЗАМЕНИТЬ(A1;ДЛСТР(A1)-2;3;ТЕКСТ(ЗНАЧЕН(ПРАВСИМВ(A1;3))*1,1;"0"));A1)

Как работает формула

• ПРАВСИМВ(A1;3) — берёт последние 3 символа из ячейки A1.
• ЗНАЧЕН(...) — пытается преобразовать эти символы в число.
• *1,1 — увеличивает число на 10%. В русском Excel дробная часть отделяется запятой.
• ТЕКСТ(...;"0") — преобразует результат обратно в текст (без дробной части).
• ЗАМЕНИТЬ(...) — подставляет полученное значение вместо последних 3 символов.
• ЕСЛИОШИБКА(...;A1) — если последние 3 символа не число (например, "XYZ"), возвращается исходное значение A1.

ЗАМЕНИТЬ или ПОДСТАВИТЬ

ЗАМЕНИТЬ меняет символы по номеру позиции и не смотрит, что в них написано. ПОДСТАВИТЬ ищет конкретный текст и меняет все его вхождения, где бы они ни стояли.

Ошибки функции ЗАМЕНИТЬ

• #ЗНАЧ!. Начальная позиция меньше 1 или вложенный ПОИСК не нашёл символ. Проверьте позицию или оберните формулу в ЕСЛИОШИБКА.
• Дата превратилась в число. ЗАМЕНИТЬ работает с текстом, а дата для Excel — число. Сначала переведите дату в текст функцией ТЕКСТ.
• Число стало текстом. Результат ЗАМЕНИТЬ всегда текст. Чтобы считать с ним, поставьте перед формулой два минуса: =--ЗАМЕНИТЬ(…).
• Заменилось не то место. ЗАМЕНИТЬ не ищет текст. Если позиция фрагмента в строках разная, используйте ПОДСТАВИТЬ или вычисляйте позицию через ПОИСК.

Функция ЗАМЕНИТЬ — частые вопросы

Как работает функция ЗАМЕНИТЬ в Excel?

Она берёт текст, начальную позицию, число символов и новый фрагмент: =ЗАМЕНИТЬ(A2;5;3;"777").

Как заменить часть текста в ячейке?

По позиции — ЗАМЕНИТЬ, по содержимому — =ПОДСТАВИТЬ(A2;"старое";"новое"). Во всех ячейках сразу — Ctrl+H.

Как вставить символ в середину текста?

ЗАМЕНИТЬ с нулём символов: =ЗАМЕНИТЬ(A2;4;0;"-").

Как удалить символы функцией ЗАМЕНИТЬ?

Укажите пустую строку: =ЗАМЕНИТЬ(A2;1;3;"") удалит первые 3 символа.

Как называется ЗАМЕНИТЬ на английском?

REPLACE.

Итоги: функция ЗАМЕНИТЬ в Excel

Надеюсь, на этой странице вы нашли то, что искали. ЗАМЕНИТЬ хороша, когда известна позиция; когда известен сам текст — берите ПОДСТАВИТЬ.

Функция НАЙТИ в Excel возвращает позицию, с которой текст встречается в строке: =НАЙТИ("@";A2) покажет, каким по счёту символом стоит «@». Поиск учитывает регистр («А» и «а» — разные буквы) и не поддерживает подстановочные знаки — в этом её отличие от ПОИСК. Если фрагмента нет, НАЙТИ возвращает #ЗНАЧ!, поэтому проверку «содержит ли ячейка текст» пишут так: =ЕЧИСЛО(НАЙТИ("ООО";A2)). Чаще всего НАЙТИ используют вместе с ЛЕВСИМВ и ПСТР, чтобы вырезать текст до или после символа. На английском функция называется FIND.

Что делает функция НАЙТИ?

Эта функция ищет текст внутри другого фрагмента текста регистрозависимым поиском. Это отличает ее от функции ПОИСК, при абсолютно идентичном синтаксисе. Второе отличие - она не поддерживает подстановочные символы, воспринимая их обычным образом.

Когда искомое найдено, отображается его позиция в тексте в виде числа. Если текст содержит более одного вхождения, выводится позиция первого.

Третий опциональный параметр - чтобы найти фрагмент c определенной позиции в тексте.

Если искомое не найдено в тексте, функция возвращает ошибку #ЗНАЧ!.

НАЙТИ - Синтаксис функции

Синтаксис функции "НАЙТИ":

=НАЙТИ(искомый_текст;просматриваемый_текст;[нач_позиция])

НАЙТИ: формат результата и исходных данных

См. Функция ПОИСК

Функция НАЙТИ - примеры

Если регистр не важен, лучше использовать функцию ПОИСК и примеры брать оттуда.

НАЙТИ вместе с ЛЕВСИМВ и ПСТР

Позиция, которую возвращает НАЙТИ, — готовая граница для вырезания текста: =ЛЕВСИМВ(A2;НАЙТИ("@";A2)-1) возьмёт всё до «@», а =ПСТР(A2;НАЙТИ("@";A2)+1;100) — всё после.

Найти заглавные буквы (кириллицы и латиницы)

Функция чувствительна к регистру символов, что позволяет с ее помощью, например, найти заглавные буквы в Excel. Решение ниже, правда, не самое изящное, есть варианты и попроще (в статье по ссылке).

=СЧЁТ(НАЙТИ({"A";"B";"C";"D";"E";"F";"G";"H";"I";"J";"K";"L";"M";"N";"O";"P";"Q";"R";"S";"T";"U";"V";"W";"X";"Y";"Z";"А";"Б";"В";"Г";"Д";"Е";"Ё";"Ж";"З";"И";"Й";"К";"Л";"М";"Н";"О";"П";"Р";"С";"Т";"У";"Ф";"Х";"Ц";"Ч";"Ш";"Щ";"Ъ";"Ы";"Ь";"Э";"Ю";"Я"};A1))>0

Найти заглавные английские буквы в ячейке

Можно воспользоваться аналогом формулы выше, убрав из нее кириллицу, но можно и более изящной формулой массива.

Помогут составить такую формулу функция СЧЕТ и функция СИМВОЛ:

{=СЧЁТ(НАЙТИ(СИМВОЛ(СТРОКА(65:90));A1))>0}

Формула также вернет ИСТИНА или ЛОЖЬ.

Важно: формула массива вводится без фигурных скобок сочетанием клавиш Ctrl + Shift + Enter.

Найти заглавные русские буквы в ячейке

Формула аналогична предыдущей, разница лишь в диапазоне символов - от 192 до 223:

{=СЧЁТ(НАЙТИ(СИМВОЛ(СТРОКА(192:223));A1))>0}

Смотрите также:

Найти определенные символы в ячейках Excel

Найти числа/цифры в тексте Excel

Почему НАЙТИ возвращает #ЗНАЧ! — частые ошибки

• Не совпадает регистр. НАЙТИ различает «А» и «а» — если регистр не важен, используйте ПОИСК.
• Используются * или ?. НАЙТИ не понимает подстановочные знаки, ищет их как обычные символы.
• Начальная позиция больше длины текста или меньше 1.
• Перепутаны аргументы. Сначала что ищем, потом где: =НАЙТИ("@";A2), а не наоборот.
• Разделители аргументов. В русском Excel — точка с запятой.

Функция НАЙТИ — частые вопросы

Что делает функция НАЙТИ в Excel?

Возвращает номер символа, с которого начинается искомый текст: =НАЙТИ("@";A2).

Чем НАЙТИ отличается от ПОИСК?

НАЙТИ учитывает регистр и не поддерживает * и ?; ПОИСК — наоборот.

Как проверить, содержит ли ячейка текст?

Формулой =ЕЧИСЛО(НАЙТИ("текст";A2)) — вернёт ИСТИНА или ЛОЖЬ.

Как НАЙТИ называется на английском?

FIND. Формула =НАЙТИ("@";A2) в английском Excel — =FIND("@",A2).

Как найти текст на листе, а не в формуле?

Для поиска по листу используйте Ctrl+F; функция НАЙТИ работает внутри одной ячейки.

Итоги: функция НАЙТИ в Excel

Надеюсь, на этой странице вы нашли то, что искали. НАЙТИ — точный, регистрозависимый поиск позиции; для поиска без учёта регистра и с шаблонами берите ПОИСК.

Функция ПРОПНАЧ в Excel делает первую букву каждого слова заглавной, а остальные — строчными: =ПРОПНАЧ("договор на согласование") вернёт «Договор На Согласование», =ПРОПНАЧ(A2) превратит «ИВАНОВ иван» в «Иванов Иван». Новым словом функция считает всё, что идёт после любого небуквенного символа: пробела, дефиса, кавычки, цифры. Поэтому «ООО» станет «Ооо», а «кое-что» — «Кое-Что». Если заглавной должна быть только первая буква ячейки, используйте =ПРОПИСН(ЛЕВСИМВ(A2))&СТРОЧН(ПСТР(A2;2;1000)). На английском функция называется PROPER.

Что делает функция ПРОПНАЧ

Эта функция преобразует первую букву каждого слова в верхний регистр, а все последующие буквы - в нижний.

Исходный регистр букв при этом не имеет значения и не учитывается.

Разделителем слов считается любой символ, не являющийся буквой, т.е. это может быть не только пробел, но любой знак препинания, цифра или специальный символ.

Синтаксис функции ПРОПНАЧ

=ПРОПНАЧ(Текст)

ПРОПНАЧ: формат результата и исходных данных

Как и все текстовые функции, функция превращает числовые значения в строковый формат числа. Дата и дата-время при этом станут натуральными числами в текстовом формате, проценты будут переведены в десятичную дробь, а финансовые значения потеряют как единицу измерения, так и характерное форматирование.

Это нужно учитывать, если при обработке больших массивов данных в ячейках помимо текстовых значений могут быть числовые.

Строковый формат на выходе легко распознается - результат применения функции в ячейке имеет выравнивание по левому краю, в отличие от чисел, которые имеют выравнивание по правому.

Пример ПРОПНАЧ: первое слово ячейки с заглавной буквы

Как сделать первое слово с заглавной буквы в Excel? Не все слова, а только первое? В этом нам и поможет функция ПРОПНАЧ, но в комбинации с другими.

Алгоритмически задача решается в несколько простых шагов:

1. Извлекаем из исходной строки первое слово
2. Применяем к нему функцию ПРОПНАЧ
3. Извлекаем из исходной строки оставшуюся от первого слова часть (иными словами, нужно удалить первое слово из ячейки и посмотреть на результат).
4. Объединяем эти два фрагмента

Первый шаг подробно описан тут в примере 1:

Извлечь первое слово из ячейки в Excel с помощью ЛЕВСИМВ

А формула для ячейки A1 будет такой:

=ЛЕВСИМВ(A1;ПОИСК(" ";A1)-1)

Вторым шагом мы применим функцию ПРОПНАЧ к этому выражению:

=ПРОПНАЧ(ЛЕВСИМВ(A1;ПОИСК(" ";A1)-1))

Третий шаг - тут:

Удалить первое слово в ячейке Excel

Здесь формула будет такой:

=ЗАМЕНИТЬ(A1;1;ПОИСК(" ";A1);" ")

Ну а четвертый шаг - объединение этих выражений - можно совершить с помощью символа амперсанда:

=ПРОПНАЧ(ЛЕВСИМВ(A1;ПОИСК(" ";A1)-1)) & ЗАМЕНИТЬ(A1;1;ПОИСК(" ";A1);" ")

Но, к сожалению, эта формула еще не идеальна и не будет работать, если в ячейке всего одно слово (выдаст ошибку поиск пробела). Поэтому нам придется и ее обернуть функцией ЕСЛИОШИБКА и применить обычную функцию ПРОПНАЧ в случае такой ошибки:

=ЕСЛИОШИБКА(ПРОПНАЧ(ЛЕВСИМВ(A1;ПОИСК(" ";A1)-1)) & ЗАМЕНИТЬ(A1;1;ПОИСК(" ";A1);" ");ПРОПНАЧ(A1))

Идеальна ли эта формула для всех случаев? К сожалению, нет, т.к. ей присуща нехорошая особенность функции ПРОПНАЧ. Она изменяет регистр невзирая на исходный.
Например, если первое слово является аббревиатурой и все буквы в нем заглавные, функция изменит в аббревиатуре регистр всех букв, кроме первой, на нижний.

Есть ли решение этой проблемы? Да, его предлагает моя надстройка.

Заглавная только первая буква ячейки

Если нужно «как в предложении» — первая буква заглавная, остальные строчные, — ПРОПНАЧ не подходит. Соберите результат из ПРОПИСН для первой буквы и СТРОЧН для остального текста.

Подробнее о том, как изменить регистр символов и получить желаемый результат: изменить регистр в Excel.

Почему ПРОПНАЧ работает не так — частые ошибки

• Аббревиатуры стали «Ооо», «Рф». ПРОПНАЧ делает строчными все буквы, кроме первой. Аббревиатуры исправляют отдельно — заменой или процедурой !SEMTools.
• Заглавные после дефиса и апострофа: «Кое-Что», «O'Нил». Для функции это начало нового слова.
• Заглавная после цифры: «2В1», «3Д». Цифра тоже считается разделителем слов.
• Дата превратилась в число. Как и все текстовые функции, ПРОПНАЧ работает со значением ячейки, а не с её видом.

Функция ПРОПНАЧ — частые вопросы

Что делает функция ПРОПНАЧ в Excel?

Делает первую букву каждого слова заглавной, а остальные — строчными.