ЕСЛИ

Что делает эта функция?

Функция проверят истинность первого аргумента – вычисления или значения ячейки. В зависимости от результата будут выполнены вычисления или возвращены другие значения.

Синтаксис

=ЕСЛИ(Условие;ЕслиИстина;ЕслиЛожь)

=ЕСЛИ(Условие;ЕслиИстина;ЕслиЛожь)

Условие обычно является вычислением, возвращающим булевый результат (ИСТИНА или ЛОЖЬ).

Критерии сравнения, которые при этом обычно используются: ‘=’ (равно), ‘>’ (больше), ‘<‘ (меньше), ‘<>’ (не равно), ‘>=’ (больше или равно), ‘<=’ (меньше или равно). Сравнивать между собой можно и логические, и цифровые, и текстовые значения.

Функция может принимать на вход и числа. Числа, не равные нулю, считаются эквивалентны ИСТИНА, 0 – ЛОЖЬ.

Другие особенности функции ЕСЛИ:

• Если входящее значение дано как массив, функция ЕСЛИ обработает каждый элемент этого массива.

Примеры применения

Пример 1

Как проверить, что ячейка содержит цифры? На этом сайте есть детальное рассмотрение решения этой задачи, в том числе с помощью надстройки !SEMTools, которая наиболее быстро позволяет ее решить. Но сейчас мы рассмотрим ее именно с помощью ЕСЛИ.

Можно проверить, содержит ли она каждую из цифр, поочередно, и если не содержит ни одной, сообщить, что не содержит. Общий псевдо-синтаксис для проверки на истинность нескольких значений будет вовлекать вложение функции ИЛИ.

=ЕСЛИ(СЧЁТ(Проверка1;Проверка2;...);ЕслиИстина;ЕслиЛожь)

Здесь СЧЁТ вернет нам положительное число, если не равно нулю или ошибке хотя бы одно из выражений, подаваемых ему на вход (в скобках после него), или 0, если нет. А функция ЕСЛИ обработает этот результат как ИСТИНА, если число будет положительным, и как ЛОЖЬ, если оно будет равно нулю.

Для проверки вхождения цифр в строку мы воспользуемся функцией ПОИСК.

Попробуем переложить синтаксис на пример с цифрами. Так будет выглядеть формула (не удивляйтесь переносам строки и пробелам – они не учитываются в Excel и вы можете для удобства составлять сложные формулы так же).

Пример 2

Как ускорить ВПР в 50.000 раз? С помощью ЕСЛИ и второго ВПР! Нет, здесь нет ошибки. Подробно об этом увлекательном феномене можно почитать в соответствующей статье про функцию ВПР, а здесь лишь будет приведен файл и формула с участием ЕСЛИ.

Так выглядит ее синтаксис:

=ЕСЛИ(ВПР(A1;$E$1:$E$400000;1;1)=A1;ВПР(A1;$E$1:$F$400000;2;1);"")

Переводя на человеческий язык, формула означает, что если возвращенное бинарным поиском значение в первом столбце равно искомому, мы производим второй бинарный поиск – возвращая уже второй столбец. А если нет – возвращаем пустую строку.

Пример 3

В версях Excel до 2016 отсутствуют функции МАКСЕСЛИ и МИНЕСЛИ. Но нам ничто не мешает создать их аналог с помощью формул массива.

Допустим, мы хотим посчитать наибольшее и наименьшее четное число в диапазоне A1:A10.

Используем на массиве функцию ЕЧЁТН (Появилась в Excel 2007) и будем возвращать само число, если оно чётное, и пустую строку, если нечётное. Итоговый массив обработаем функциями МАКС и МИН:

Наибольшее чётное число в диапазоне:

={МАКС(ЕСЛИ(ЕЧЁТН(A1:A10+0);A1:A10;""))}

Наименьшее чётное число в диапазоне:

={МИН(ЕСЛИ(ЕЧЁТН(A1:A10+0);A1:A10;""))}

А если у нас Excel 2003 и функция ЕЧЁТН для нас тоже недоступна, используем функцию ОСТАТ, проверяя остаток от деления на 2:

Наименьшее чётное число в диапазоне (Excel 2003)

={МАКС(ЕСЛИ(ОСТАТ(A1:A10;2)=0;A1:A10;""))}

Наибольшее чётное число в диапазоне (Excel 2003)

={МИН(ЕСЛИ(ОСТАТ(A1:A10;2)=0;A1:A10;""))}

Несколько вложенных ЕСЛИ

Бывает, что одного ЕСЛИ недостаточно. Например, нужно проверить сразу несколько вариантов и для каждого показать свой результат. В таких случаях используют несколько вложенных ЕСЛИ — один внутри другого. Это удобно, когда нужно подобрать текст или значение в зависимости от множества условий.

Например, следующая формула может быть использована в Excel-документе, где вы автоматически подставляете правильное склонение фразы “календарный день” в зависимости от количества дней — например, в заявлении на отпуск или служебной записке.

Пример ситуации:

Сотрудник заполняет заявление на отпуск и в ячейке M7 указывает количество дней (например, 3, 5, 14 и т. д.).

В русском языке слово «день» меняется в зависимости от числа:

• 1 → календарный день
• 2–4 → календарных дня
• 5 и выше, а также 11–14 → календарных дней

=ЕСЛИ(ИЛИ(ПРАВСИМВ(M7;2)={"11";"12";"13";"14"});
"календарных дней";
ЕСЛИ(ИЛИ(ПРАВСИМВ(M7;1)={"2";"3";"4"});
"календарных дня";
ЕСЛИ(ПРАВСИМВ(M7;1)="1";
"календарный день";
"календарных дней")))

Чтобы автоматически выбрать правильную форму, формула выше проверяет последние символы в ячейке функцией ПРАВСИМВ:

• ПРАВСИМВ(M7;2) — две последние цифры, чтобы отловить исключения 11, 12, 13, 14
• ПРАВСИМВ(M7;1) — последнюю цифру, чтобы выбрать день / дня / дней

В итоге формула автоматически генерирует на основе числа дней правильную фразу:

• если M7 = 1 → “календарный день”
• если M7 = 2, 3, 4 → “календарных дня”
• если M7 = 5, 6, 11, 12, 13, 14, 25 и т. д. → “календарных дней”

А эту фразу уже можно использовать в тексте заявления с помощью конкатенации (СЦЕП, СЦЕПИТЬ или амперсандом “&”).

Это избавляет от ручной корректировки текста в заявлениях и других документах, где важно соблюсти правила русского языка при склонении числительных.

Когда ЕСЛИ слишком много

Если вы используете несколько вложенных ЕСЛИ, формула становится длинной и неудобной:

=ЕСЛИ(A1=1;"Один";ЕСЛИ(A1=2;"Два";ЕСЛИ(A1=3;"Три";"Другое")))

Альтернативы вложенным ЕСЛИ, такие как ВПР и ВЫБОР, помогают сделать формулы проще, понятнее и удобнее в редактировании.

✅ Зачем функция ВЫБОР

Если A1 — это просто номер (например, 1, 2, 3), формулу можно упростить:

=ВЫБОР(A1;"Один";"Два";"Три";"Четыре")

Если A1 = 3, результат будет “Три”.

🔍 Зачем ВПР

Если у вас есть таблица соответствий:

Вы можете использовать ВПР (вертикальный просмотр по таблице):

=ВПР(A1;A2:B5;2;0)

Это особенно удобно, когда вы хотите менять значения прямо в таблице, а не в самой формуле.

🧠 Вывод

• ЕСЛИ — хорошо для 2-3 условий
• ВЫБОР — идеально, если есть порядковый номер
• ВПР — удобно, когда значения хранятся в таблице