Функция ИЛИ в Excel возвращает ИСТИНА, если выполнено хотя бы одно из условий: =ИЛИ(A2="Москва";A2="Тула") — город один из двух, =ИЛИ(B2<3;C2="нет") — двойка или нет допуска. Обычно ИЛИ вкладывают в ЕСЛИ: =ЕСЛИ(ИЛИ(B2<3;C2="нет");"пересдача";"зачёт"). Проверить ячейку сразу по списку значений можно короче: =ИЛИ(A2=$D$2:$D$10). В формулах массива (ФИЛЬТР, СУММПРОИЗВ) роль «или» играет знак +.

Что делает функция ИЛИ?

Эта функция проверяет два или более условий, чтобы проверить, верно ли хотя бы одно из них. Выражаясь математическим языком, производит операцию дизъюнкции.

Критерии сравнения, которые можно использовать: '=' (равно), '>' (больше), '<' (меньше), '<>' (не равно), '>=' (больше или равно), '<=' (меньше или равно). Сравнивать можно и логические, и цифровые, и текстовые значения.

Обычно функция ИЛИ используется в паре другими логическими, наиболее часто с функцией ЕСЛИ.

Синтаксис формул с функцией ИЛИ

=ИЛИ(Выражение1;Выражение2;…)

или

=ИЛИ(диапазон_или_массив)

Знак ИЛИ (дизъюнкции) ∪ в Excel

Значок ИЛИ в Excel ("∪") можно получить с помощью функции ЮНИСИМВ.

Это не оператор, а обычный текстовый символ. Он может быть использован исключительно для текстовой записи математических выражений. Текст формулы:

=ЮНИСИМВ(8746)

ИЛИ: формат результата и исходных данных

Функция корректно обработает:

• Числа и вычисления, возвращающие их
• Логические выражения (ИСТИНА, ЛОЖЬ) и вычисления, возвращающие их
• Ячейки, содержащие их
• Диапазоны ячеек, если хотя бы одна ячейка содержит числа, ИСТИНА или ЛОЖЬ
• Массивы значений или вычислений

Если на вход подается диапазон, в значениях которого присутствуют текстовые значения, они не учитываются функцией, как и пустые ячейки.

Функция выдаст ошибку, если:

• на вход получены только текстовые или пустые ячейки (одна или несколько)
• среди значений есть ошибки (#ЗНАЧ!, #Н/Д, #ИМЯ?, #ПУСТО!, #ДЕЛ/0!, #ССЫЛКА!, #ЧИСЛО!)

Примеры формул с функцией ИЛИ

Рассмотрим пару сложных примеров применения функции ИЛИ.

Пример 1

Как правило, если слово состоит из только гласных или только согласных букв - это аббревиатура

Воспользуемся комбинацией - функция ИЛИ + функция ЕЧИСЛО + функция ПОИСК, чтобы определить на основе этого признака, что слово является аббревиатурой

Это поможет нам далее исправить регистр слова функцией ПРОПИСН, если оно изначально написано в нижнем.

Составим формулы массива для поиска гласных и согласных букв.

Для гласных:

=ИЛИ(ЕЧИСЛО(ПОИСК({"а";"о";"у";"и";"ы";"э";"я";"е";"ё";"ю"};A1)))

Для согласных:

=ИЛИ(ЕЧИСЛО(ПОИСК({"б";"в";"г";"д";"ж";"з";"й";"к";"л";"м";"н";"п";"р";"с";"т";"ф";"х";"ц";"ч";"ш";"щ"};A1)))

Теперь составим общую формулу проверки.

Для того, чтобы соблюдалось условие аббревиатуры, условия наличия гласных и согласных должны противоречить друг другу

Т.е. есть гласные и нет согласных, или, наоборот, есть согласные, но нет гласных.

Самым коротким способом записать это можно функцией НЕ.

Пример 2

Студенты получают оценки в виде букв A-F, каждая из букв может быть с плюсом. "F" и "F+" - неудовлетворительные оценки. Задача с помощью одной формулы узнать, нужна ли студенту пересдача.

Почему фигурные скобки в формуле присутствуют дважды?

Используется массив внутри формулы массива - таблица оценок студента сравнивается с массивом строковых констант "F" и "F+".

Столбец оценок - вертикальный, а массив строковых констант - горизонтальный. При сравнении этих двух массивов (в скобках) , возвращается массив булевых значений размерностью 5 на 2.

Функция ИЛИ возвращает ИСТИНА, если в этом массиве есть хотя бы одна неудовлетворительная оценка.

«ИЛИ» в ФИЛЬТР и СУММПРОИЗВ

ИЛИ всегда возвращает одно значение на весь массив, поэтому внутри ФИЛЬТР, СУММПРОИЗВ и других функций, которые проверяют каждую строку, её заменяют сложением условий.

Другие логические функции

ЕСЛИ, И, НЕ

Почему ИЛИ работает не так — частые ошибки

• Формула вида =A2="Москва" ИЛИ "Тула" не работает. Каждое условие пишется полностью: =ИЛИ(A2="Москва";A2="Тула").
• ИЛИ в ФИЛЬТР отбирает всё или ничего. Внутри массивов используйте сложение условий (…)+(…).
• #ЗНАЧ!. В аргументах только текст или пустые ячейки — сравнивайте значения, а не передавайте их напрямую.
• Нужно, чтобы выполнялись все условия. Тогда используйте И.

Функция ИЛИ — частые вопросы

Как работает функция ИЛИ в Excel?

Возвращает ИСТИНА, если хотя бы одно условие верно: =ИЛИ(A2>5;B2>5).

Как использовать ИЛИ вместе с ЕСЛИ?

Вложите ИЛИ в ЕСЛИ: =ЕСЛИ(ИЛИ(A2="Москва";A2="Тула");"центр";"регион").

Есть ли в Excel знак «или»?

Оператора нет, но условия можно складывать: =(A2>5)+(B2>5)>0. Символ ∪ выводит =ЮНИСИМВ(8746).

Как проверить, совпадает ли ячейка с любым значением из списка?

Формулой =ИЛИ(A2=$D$2:$D$10).

Как называется ИЛИ на английском?

OR.

Итоги: функция ИЛИ в Excel

Надеюсь, на этой странице вы нашли то, что искали. ИЛИ объединяет условия «хотя бы одно из», а для построчных проверок в массивах её заменяет знак +.

Функция ЕСЛИ в Excel проверяет условие и возвращает одно значение, если оно выполнено, и другое — если нет: =ЕСЛИ(B2>=50;"Зачёт";"Незачёт"). В условии используют сравнения =, >, <, <>, >=, <=, а несколько условий объединяют через И и ИЛИ: =ЕСЛИ(И(A2>=10;A2<=20);"в диапазоне";"вне"). Проверка «если ячейка содержит текст» записывается как =ЕСЛИ(ЕЧИСЛО(ПОИСК("опт";A2));"Опт";"Розница"), а «если в ячейке число» — =ЕСЛИ(ЕЧИСЛО(A2);…;…). Для многих вариантов ЕСЛИ вкладывают друг в друга или заменяют на ЕСЛИМН, ВЫБОР и ВПР. На английском функция называется IF.

Что делает функция ЕСЛИ

Функция проверят истинность первого аргумента - вычисления или значения ячейки. В зависимости от результата будут выполнены вычисления или возвращены другие значения.

Синтаксис функции ЕСЛИ

=ЕСЛИ(Условие;ЕслиИстина;ЕслиЛожь)

Условие обычно является вычислением, возвращающим булевый результат (ИСТИНА или ЛОЖЬ).

Критерии сравнения, которые при этом обычно используются: '=' (равно), '>' (больше), '<' (меньше), '<>' (не равно), '>=' (больше или равно), '<=' (меньше или равно). Сравнивать между собой можно и логические, и цифровые, и текстовые значения.

Функция может принимать на вход и числа. Числа, не равные нулю, считаются эквивалентны ИСТИНА, 0 - ЛОЖЬ.

Другие особенности функции ЕСЛИ:

• Если входящее значение дано как массив, функция ЕСЛИ обработает каждый элемент этого массива.

Если ячейка содержит текст или число

ЕСЛИ не умеет искать часть текста сама — для этого внутрь ставят ПОИСК (без учёта регистра) или НАЙТИ (с учётом) и проверяют результат функцией ЕЧИСЛО. Тип значения проверяют функциями ЕЧИСЛО, ЕТЕКСТ и ЕПУСТО.

Несколько условий: ЕСЛИМН вместо вложенных ЕСЛИ

В Excel 2019 и 365 вместо цепочки ЕСЛИ можно перечислить пары «условие; результат» в одной функции ЕСЛИМН. Последнее условие ИСТИНА работает как «во всех остальных случаях».

Примеры формул с функцией ЕСЛИ

Пример 1

Как проверить, что ячейка содержит цифры? На этом сайте есть детальное рассмотрение решения этой задачи, в том числе с помощью надстройки !SEMTools, которая наиболее быстро позволяет ее решить. Но сейчас мы рассмотрим ее именно с помощью ЕСЛИ.

Можно проверить, содержит ли она каждую из цифр, поочередно, и если не содержит ни одной, сообщить, что не содержит. Общий псевдо-синтаксис для проверки на истинность нескольких значений будет вовлекать вложение функции ИЛИ.

=ЕСЛИ(СЧЁТ(Проверка1;Проверка2;...);ЕслиИстина;ЕслиЛожь)

Здесь СЧЁТ вернет нам положительное число, если не равно нулю или ошибке хотя бы одно из выражений, подаваемых ему на вход (в скобках после него), или 0, если нет. А функция ЕСЛИ обработает этот результат как ИСТИНА, если число будет положительным, и как ЛОЖЬ, если оно будет равно нулю.

Для проверки вхождения цифр в строку мы воспользуемся функцией ПОИСК.

Попробуем переложить синтаксис на пример с цифрами. Так будет выглядеть формула (не удивляйтесь переносам строки и пробелам - они не учитываются в Excel и вы можете для удобства составлять сложные формулы так же).

=ЕСЛИ(СЧЁТ(ПОИСК({0;1;2;3;4;5;6;7;8;9};A2));"Есть цифры";"Нет цифр")

Пример 2

Как ускорить ВПР в 50.000 раз? С помощью ЕСЛИ и второго ВПР! Нет, здесь нет ошибки. Подробно об этом увлекательном феномене можно почитать в соответствующей статье про функцию ВПР, а здесь лишь будет приведен файл и формула с участием ЕСЛИ.

Так выглядит ее синтаксис:

=ЕСЛИ(ВПР(A1;$E$1:$E$400000;1;1)=A1;ВПР(A1;$E$1:$F$400000;2;1);"")

Переводя на человеческий язык, формула означает, что если возвращенное бинарным поиском значение в первом столбце равно искомому, мы производим второй бинарный поиск - возвращая уже второй столбец. А если нет - возвращаем пустую строку.

Пример 3

В версях Excel до 2016 отсутствуют функции МАКСЕСЛИ и МИНЕСЛИ. Но нам ничто не мешает создать их аналог с помощью формул массива.

Допустим, мы хотим посчитать наибольшее и наименьшее четное число в диапазоне A1:A10.

Используем на массиве функцию ЕЧЁТН (Появилась в Excel 2007) и будем возвращать само число, если оно чётное, и пустую строку, если нечётное. Итоговый массив обработаем функциями МАКС и МИН:

Наибольшее чётное число в диапазоне:

={МАКС(ЕСЛИ(ЕЧЁТН(A1:A10+0);A1:A10;""))}

Наименьшее чётное число в диапазоне:

={МИН(ЕСЛИ(ЕЧЁТН(A1:A10+0);A1:A10;""))}

А если у нас Excel 2003 и функция ЕЧЁТН для нас тоже недоступна, используем функцию ОСТАТ, проверяя остаток от деления на 2:

Наибольшее чётное число в диапазоне (Excel 2003)

={МАКС(ЕСЛИ(ОСТАТ(A1:A10;2)=0;A1:A10;""))}

Наименьшее чётное число в диапазоне (Excel 2003)

={МИН(ЕСЛИ(ОСТАТ(A1:A10;2)=0;A1:A10;""))}

Несколько вложенных ЕСЛИ

Бывает, что одного ЕСЛИ недостаточно. Например, нужно проверить сразу несколько вариантов и для каждого показать свой результат. В таких случаях используют несколько вложенных ЕСЛИ — один внутри другого. Это удобно, когда нужно подобрать текст или значение в зависимости от множества условий.

Например, следующая формула может быть использована в Excel-документе, где вы автоматически подставляете правильное склонение фразы "календарный день" в зависимости от количества дней — например, в заявлении на отпуск или служебной записке.

Пример ситуации:

Сотрудник заполняет заявление на отпуск и в ячейке M7 указывает количество дней (например, 3, 5, 14 и т. д.).

В русском языке слово «день» меняется в зависимости от числа:

• 1 → календарный день
• 2–4 → календарных дня
• 5 и выше, а также 11–14 → календарных дней

=ЕСЛИ(ИЛИ(ПРАВСИМВ(M7;2)={"11";"12";"13";"14"});
"календарных дней";
ЕСЛИ(ИЛИ(ПРАВСИМВ(M7;1)={"2";"3";"4"});
"календарных дня";
ЕСЛИ(ПРАВСИМВ(M7;1)="1";
"календарный день";
"календарных дней")))

Чтобы автоматически выбрать правильную форму, формула выше проверяет последние символы в ячейке функцией ПРАВСИМВ:

• ПРАВСИМВ(M7;2) — две последние цифры, чтобы отловить исключения 11, 12, 13, 14
• ПРАВСИМВ(M7;1) — последнюю цифру, чтобы выбрать день / дня / дней

В итоге формула автоматически генерирует на основе числа дней правильную фразу:

• если M7 = 1 → "календарный день"
• если M7 = 2, 3, 4 → "календарных дня"
• если M7 = 5, 6, 11, 12, 13, 14, 25 и т. д. → "календарных дней"

А эту фразу уже можно использовать в тексте заявления с помощью конкатенации (СЦЕП, СЦЕПИТЬ или амперсандом "&").

Это избавляет от ручной корректировки текста в заявлениях и других документах, где важно соблюсти правила русского языка при склонении числительных.

Когда ЕСЛИ слишком много

Если вы используете несколько вложенных ЕСЛИ, формула становится длинной и неудобной:

=ЕСЛИ(A1=1;"Один";ЕСЛИ(A1=2;"Два";ЕСЛИ(A1=3;"Три";"Другое")))

Альтернативы вложенным ЕСЛИ, такие как ВПР и ВЫБОР, помогают сделать формулы проще, понятнее и удобнее в редактировании.

✅ Зачем функция ВЫБОР

Если A1 — это просто номер (например, 1, 2, 3), формулу можно упростить:

=ВЫБОР(A1;"Один";"Два";"Три";"Четыре")

Если A1 = 3, результат будет "Три".

🔍 Зачем ВПР

Если у вас есть таблица соответствий:

Вы можете использовать ВПР (вертикальный просмотр по таблице):

=ВПР(A1;A2:B5;2;0)

Это особенно удобно, когда вы хотите менять значения прямо в таблице, а не в самой формуле.

🧠 Вывод

• ЕСЛИ — хорошо для 2-3 условий
• ВЫБОР — идеально, если есть порядковый номер
• ВПР — удобно, когда значения хранятся в таблице

Почему ЕСЛИ работает неправильно — частые ошибки

• Текст без кавычек. Ответы-строки нужно брать в кавычки: "Да", иначе Excel вернёт #ИМЯ?.
• Условие «содержит» через звёздочки. =ЕСЛИ(A1="*текст*";…) не работает — используйте ЕЧИСЛО(ПОИСК("текст";A1)).
• Число, сохранённое как текст. "100">50 сравнивает текст с числом и всегда даёт ИСТИНА — превратите текст в число.
• Неверный порядок вложенных условий. Первое выполненное условие останавливает проверку — ставьте самые строгие пороги первыми.
• Нет третьего аргумента. Если его пропустить, при невыполненном условии ЕСЛИ вернёт ЛОЖЬ.

Функция ЕСЛИ — частые вопросы

Как работает функция ЕСЛИ в Excel?

Проверяет условие и возвращает второй аргумент, если оно истинно, и третий — если ложно: =ЕСЛИ(B2>=50;"Зачёт";"Незачёт").

Как сделать ЕСЛИ с несколькими условиями?

Через И или ИЛИ: =ЕСЛИ(И(A2>0;B2>0);"ок";"нет"), или вложенными ЕСЛИ / ЕСЛИМН для нескольких вариантов ответа.

Как прописать условие «больше и меньше»?

Двумя сравнениями внутри И: =ЕСЛИ(И(A2>=10;A2<=20);"да";"нет").

Как написать «если ячейка содержит»?

Формулой =ЕСЛИ(ЕЧИСЛО(ПОИСК("текст";A2));"да";"нет").

Как ЕСЛИ называется на английском?

IF; ЕСЛИМН — IFS, ЕСЛИОШИБКА — IFERROR.

Итоги: функция ЕСЛИ в Excel

Надеюсь, на этой странице вы нашли то, что искали. ЕСЛИ — основа логики в Excel: сравнения, И/ИЛИ и проверки ЕЧИСЛО покрывают почти все задачи, а для длинных цепочек есть ЕСЛИМН и ВПР.

Дельта в Excel — это разница между двумя значениями. Посчитать её можно без функций: абсолютная дельта — =B2-A2 («после» минус «до»), дельта в процентах — =B2/A2-1 или =(B2-A2)/A2 с процентным форматом ячейки. Функция ДЕЛЬТА (DELTA) делает другое: проверяет, равны ли два числа, и возвращает 1 или 0 — =ДЕЛЬТА(A2;B2). Символ Δ вставляет формула =ЮНИСИМВ(916).

Что делает функция ДЕЛЬТА?

Эта функция сравнивает два значения и проверяет, являются ли они абсолютно одинаковыми.

Если числа совпадают, результатом будет 1, в противном случае - 0.

Работает только с числами, текстовые значения на входе отдают результат #ЗНАЧ!

Форматирование числа не имеет существенного значения, поэтому числа, которые выглядят округленными из-за удаления десятичных разрядов, будут по-прежнему корректно соответствовать не округленным значениям.

Синтаксис ДЕЛЬТА

=ДЕЛЬТА(ПервоеЧисло;ВтороеЧисло)

Примеры с функцией ДЕЛЬТА

Следующая таблица используется для определения того, сколько одинаковых пар чисел в списке.

Функция ДЕЛЬТА проверяет каждую пару, а затем функция СУММ суммирует их.

Как посчитать дельту (разницу в процентах) в Excel

По иронии судьбы, функция ДЕЛЬТА не поможет посчитать дельту в Excel. Сравнивая данные в ячейках, функция лишь отвечает на вопрос, равна ли их дельта нулю или нет (иными словами, есть ли дельта).

А посчитать дельту между A и B можно без применения каких-либо функций вовсе, лишь зная две простые формулы ее подсчета:

Второй вариант в Excel использовать удобнее, т.к. первый требует использования скобок.

Не дайте буквам в формуле вас запутать - B обозначает первый замер (результат "до"), а A - второй (результат "после"). Иными словами, A случилось после B, их алфавитный порядок здесь не при чем.

Чтобы полученный результат выражался в процентах, нужно изменить формат ячеек на процентный:

Знак "Дельта" в Excel

Дельта Δ - это буква греческого алфавита. Если язык вашей системы русский, а не греческий, добраться до неё не так просто. Можно использовать меню "вставить символ" на вкладке "Вставка" и найти знак в юникод-таблице. Находится в наборе "греческие и коптские символы".

Но можно и проще, Чтобы получить символ дельты в Excel, нужно запомнить число 916. Именно это его номер в таблице Unicode. А функция, которая превратит число в символ - ЮНИСИМВ. Заходите в статью о функции - там много юникод-номеров полезных символов, в том числе и все греческие символы.

Другие инженерные функции

ДВ.В.ДЕС, ДЕС.В.ДВ, ДЕС.В.ШЕСТН, ПОРОГ, ПРЕОБР, ШЕСТН.В.ДЕС

Частые ошибки при расчёте дельты

• Знак получился «не тот». Дельта — это «после» минус «до». Если вычитать наоборот, рост станет отрицательным.
• #ДЕЛ/0! в процентной дельте. Значение «до» равно нулю — процентный рост от нуля не определён. Перехватите ошибку: =ЕСЛИОШИБКА(B2/A2-1;"").
• Вместо процентов — дробь вроде 0,25. У ячейки общий формат. Включите процентный формат (Ctrl+Shift+5).
• ДЕЛЬТА возвращает #ЗНАЧ!. Одно из значений — текст. Функция работает только с числами.

Дельта в Excel — частые вопросы

Что такое дельта?

Разница между двумя значениями: новое минус старое. В процентах — разница, делённая на старое значение.

Как посчитать дельту в процентах в Excel?

Формулой =B2/A2-1, где A2 — значение «до», B2 — «после», и задайте ячейке процентный формат.

Что делает функция ДЕЛЬТА?

Проверяет, равны ли два числа: 1 — равны, 0 — нет. Разницу она не считает.

Как вставить символ дельты в Excel?

Формулой =ЮНИСИМВ(916) или через «Вставка → Символ», набор «греческие».

Итоги: дельта в Excel

Надеюсь, на этой странице вы нашли то, что искали. Дельту считают простым вычитанием и делением, а функция ДЕЛЬТА нужна только для проверки равенства.

Функция ДЕС.В.ШЕСТН переводит десятичное число в шестнадцатеричное: =ДЕС.В.ШЕСТН(255) вернёт «FF», =ДЕС.В.ШЕСТН(255;4) — «00FF». Самое частое применение — код цвета: =ДЕС.В.ШЕСТН(255;2)&ДЕС.В.ШЕСТН(128;2)&ДЕС.В.ШЕСТН(0;2) даст «FF8000» для RGB(255; 128; 0). Обратный перевод делает ШЕСТН.В.ДЕС, на английском функция называется DEC2HEX.

Что делает функция ДЕС.В.ШЕСТН

Эта функция преобразует десятичное число в его шестнадцатиричный эквивалент.

Она может принимать на вход только с числа от от -549 755 813 888 до 549 755 813 887.

Результат может быть дополнен начальными нулями с помощью опционального параметра, который игнорируется для отрицательных чисел.

Синтаксис функции ДЕС.В.ШЕСТН

=ДЕС.В.ШЕСТН(ДесятиричноеЧисло;КоличествоЗнаков)

Другие инженерные функции

ДВ.В.ДЕС, ДЕЛЬТА, ДЕС.В.ДВ, ПОРОГ, ПРЕОБР, ШЕСТН.В.ДЕС

Ошибки ДЕС.В.ШЕСТН

• #ЧИСЛО!. Число вне диапазона от −549 755 813 888 до 549 755 813 887 или результат длиннее заданного числа знаков.
• Код цвета короче шести знаков. Не указано число знаков 2 для каналов меньше 16.
• Результат нельзя сложить. Это текст — для расчётов переведите обратно ШЕСТН.В.ДЕС.

Функция ДЕС.В.ШЕСТН — частые вопросы

Как перевести число в шестнадцатеричную систему?

Формулой =ДЕС.В.ШЕСТН(A2).

Как получить HEX-код цвета из RGB?

Формулой =ДЕС.В.ШЕСТН(R;2)&ДЕС.В.ШЕСТН(G;2)&ДЕС.В.ШЕСТН(B;2).

Как называется ДЕС.В.ШЕСТН на английском?

DEC2HEX. Обратная функция — HEX2DEC (ШЕСТН.В.ДЕС).

Итоги: функция ДЕС.В.ШЕСТН в Excel

Надеюсь, на этой странице вы нашли то, что искали. Для кодов цвета всегда указывайте два знака на канал.

Функция ДЕС.В.ДВ переводит десятичное число в двоичную запись: =ДЕС.В.ДВ(10) вернёт «1010», а =ДЕС.В.ДВ(5;8) — «00000101», дополнив результат нулями до 8 знаков. Функция работает с числами от −512 до 511; для больших чисел используйте =ОСНОВАНИЕ(1000;2). Обратный перевод делает ДВ.В.ДЕС, на английском функция называется DEC2BIN.

Что делает функция ДЕС.В.ДВ

Эта функция преобразует десятичное число в его двоичный эквивалент.

Она может работать только с десятиричными числами от -512 до 511.

Результат может быть дополнен нулями вначале с помощью второго параметра.

Синтаксис функции ДЕС.В.ДВ

=ДЕС.В.ДВ(ДесятиричноеЧисло;[КоличествоЗнаков])

КоличествоЗнаков - опциональный параметр. Игнорируется для отрицательных чисел (в них всегда 10 знаков).

Другие инженерные функции

ДВ.В.ДЕС, ДЕЛЬТА, ДЕС.В.ШЕСТН, ПОРОГ, ПРЕОБР, ШЕСТН.В.ДЕС

Ошибки ДЕС.В.ДВ

• #ЧИСЛО!. Число меньше −512 или больше 511, либо длина результата больше заданного числа знаков. Используйте ОСНОВАНИЕ или увеличьте второй аргумент.
• #ЗНАЧ!. В аргументе текст, который не является числом.
• Результат нельзя сложить. ДЕС.В.ДВ возвращает текст — для расчётов переводите обратно через ДВ.В.ДЕС.

Функция ДЕС.В.ДВ — частые вопросы

Как перевести число в двоичную систему в Excel?

Формулой =ДЕС.В.ДВ(A2), а для чисел больше 511 — =ОСНОВАНИЕ(A2;2).

Как дополнить двоичное число нулями?

Вторым аргументом: =ДЕС.В.ДВ(5;8) вернёт «00000101».

Как перевести двоичное число обратно в десятичное?

Функцией =ДВ.В.ДЕС("1010") или =ДЕС("1010";2).

Как называется ДЕС.В.ДВ на английском?

DEC2BIN.

Итоги: функция ДЕС.В.ДВ в Excel

Надеюсь, на этой странице вы нашли то, что искали. Для небольших чисел хватает ДЕС.В.ДВ, для остальных — ОСНОВАНИЕ.

Функция ПОРОГ в Excel возвращает 1, если число больше порогового значения или равно ему, и 0 — если меньше: =ПОРОГ(B2;C2) покажет, выполнил ли менеджер план. Сумма таких единиц — количество выполнивших: =СУММ(D2:D10). Без второго аргумента порог равен нулю. То же самое можно записать сравнением: =--(B2>=C2). На английском функция называется GESTEP.

Что делает функция ПОРОГ

Эта функция проверяет, достигает ли число определенное значение (иными словами, не меньше ли оно).

Если число больше или равно этому значению, функция возвращает результат 1, в противном случае 0.

Синтаксис функции ПОРОГ

=ПОРОГ(Число;[Порог])

Пример формулы с функцией ПОРОГ

Следующая таблица была использована для расчета того, сколько сотрудников по продажам достигли своих персональных целей. Функция ПОРОГ сравнивает продажи с целью, и результаты суммируются.

Другие инженерные функции

ДВ.В.ДЕС, ДЕЛЬТА, ДЕС.В.ДВ, ДЕС.В.ШЕСТН, ПРЕОБР, ШЕСТН.В.ДЕС

Функция ПОРОГ — частые вопросы

Что делает функция ПОРОГ?

Возвращает 1, если число не меньше порога, и 0 — если меньше.

Как посчитать, сколько значений достигли порога?

Сложите результаты ПОРОГ или используйте =СЧЁТЕСЛИ(B2:B10;">=100").

Чем ПОРОГ отличается от ДЕЛЬТА?

ДЕЛЬТА проверяет равенство чисел, ПОРОГ — «больше или равно».

Как называется ПОРОГ на английском?

GESTEP.

Итоги: функция ПОРОГ в Excel

Надеюсь, на этой странице вы нашли то, что искали. ПОРОГ удобна для подсчёта выполненных планов; в остальных случаях её легко заменить сравнением.